dev-dotnet/nant/nant-0.85_rc3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/nant/nant-0.85_rc3.ebuild,v 1.2 2005/05/13 02:27:09 latexer Exp $

inherit mono eutils

MY_P=${P/_rc/-rc}

DESCRIPTION=".NET build tool"
HOMEPAGE="http://nant.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
DEPEND=">=dev-lang/mono-1.1.4"

S=${WORKDIR}/${MY_P}

src_unpack() {
	local targetlibdir=""
	unpack ${A}
	cd ${S}

	epatch ${FILESDIR}/${PN}-0.85-rc2-is-unix.diff || die
	epatch ${FILESDIR}/${PN}-0.85-rc2-profile.diff || die
	epatch ${FILESDIR}/${MY_P}-mono-1.1.7-compat.diff || die

	# Fix a problem with duplicate building caused by the doc= target
	for file in $(find ${S}/src -name '*.build')
	do
		sed -i "s: doc=.*>:>:" \
			${file}
	done

	# Problem with is-unix() on mono-1.1.x where the platform is detected
	# as !is-unix().
	sed -i -e "s:install-windows, install-linux:install-linux:" \
		-e 's:if.*is-unix()}\"::' \
		${S}/NAnt.build || die "sed failed"

	# When we have mono-1.1.x, we should build against 2.0,
	# so that people using nant can use either the 2.0 or 1.0 profiles
	if has_version ">=dev-lang/mono-1.1.4"; then
		sed -i -e "s/-f:NAnt.build/-t:mono-2.0 -f:NAnt.build/" \
			${S}/Makefile || die "sed failed"

		targetlibdir="${S}/build/mono-2.0.unix/nant-0.85-debug/bin/lib/"
	else
		# Fix for AppDomain unloading on 1.0.x. See bug #90113
		export MONO_NO_UNLOAD=1
		targetlibdir="${S}/build/mono-1.0.unix/nant-0.85-debug/bin/lib/"
	fi

	# Fix for build problem with rc3
	mkdir -p "${targetlibdir}"
	cp ${S}/lib/log4net.dll "${targetlibdir}"
}

src_compile() {
	emake -j1 || die
}

src_install() {
	make prefix=${D}/usr install || die
	# Fix ${D} showing up in the nant wrapper script, as well as silencing
	# warnings related to the log4net library
	sed -i \
		-e "s:${D}::" \
		-e "2iexport MONO_SILENT_WARNING=1" \
		${D}/usr/bin/nant
	dodoc README.txt

	# Remove the extraneous log4net.dll copy
	rm ${D}/usr/share/NAnt/bin/lib/log4net.dll
}