dev-ml/res/res-3.2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ml/res/res-3.2.0.ebuild,v 1.3 2009/08/14 18:15:11 maekke Exp $

EAPI="2"

inherit findlib eutils

DESCRIPTION="Resizable Array and Buffer modules for O'Caml"
HOMEPAGE="http://ocaml.info/home/ocaml_sources.html"
SRC_URI="http://www.ocaml.info/ocaml_sources/${P}.tar.gz"
LICENSE="LGPL-2.1"

DEPEND=">=dev-lang/ocaml-3.10.2[ocamlopt?]"
RDEPEND="${DEPEND}"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE="doc examples +ocamlopt"

src_prepare() {
	epatch "${FILESDIR}/${P}-noocamlopt.patch"
}

src_compile() {
	cd "${S}/lib"
	emake -j1 byte-code-library || die "failed to build byte code library"
	if use ocamlopt; then
		emake -j1 native-code-library || die "failed to built nativde code library"
	fi

	if use doc; then
		emake htdoc || die "failed to build documentation"
	fi
}

src_install () {
	cd "${S}/lib"
	findlib_src_preinst
	if use ocamlopt; then
		emake DESTDIR="${D}" libinstall || die
	else
		emake DESTDIR="${D}" libinstall-byte-code || die
	fi

	cd "${S}"
	# install documentation
	dodoc TODO README.txt Changelog

	if use doc; then
		dohtml lib/doc/res/html/*
	fi
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}