dev-util/ragel/ragel-6.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/ragel/ragel-6.3.ebuild,v 1.6 2009/05/30 08:26:31 ulm Exp $

EAPI=2

inherit eutils

DESCRIPTION="Compiles finite state machines from regular languages into executable code."
HOMEPAGE="http://www.complang.org/ragel/"
SRC_URI="http://www.complang.org/ragel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc vim-syntax"

DEPEND="
	doc? (
		app-text/texlive-core
		dev-texlive/texlive-latexextra
		media-gfx/transfig
	)"
RDEPEND=""

src_prepare() {
	find "${S}" -iname "Makefile*" -exec sed -i \
		-e "s:install -s:install:" \
		-e '/\$(CXX)/s:CFLAGS:CXXFLAGS:' \
		{} \;
}

src_compile() {
	emake || die

	pushd doc
	emake ragel.1 rlgen-{cd,java,ruby,dot}.1 || die
	popd

	if use doc ; then
		pushd doc
		emake ragel-guide.pdf || die
		popd
	fi
}

src_install() {
	einstall || die

	for i in cd java ruby dot; do
		dobin rlgen-${i}/rlgen-${i}
	done
	doman doc/ragel.1 doc/rlgen-{cd,java,ruby,dot}.1
	dodoc ChangeLog CREDITS README TODO

	if use doc; then
		insinto /usr/share/doc/"${PF}"
		doins doc/ragel-guide.pdf
	fi

	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/syntax
		doins ragel.vim
	fi
}