blob: 2a4b19bc3c2293c221884a35039fb5dbfb56edb0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/eboard/eboard-1.1.1.ebuild,v 1.7 2009/06/18 01:48:47 nyhm Exp $
EAPI=2
inherit eutils games
EXTRAS1="eboard-extras-1pl2"
EXTRAS2="eboard-extras-2"
DESCRIPTION="chess interface for POSIX systems"
HOMEPAGE="http://www.bergo.eng.br/eboard/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
mirror://sourceforge/${PN}/${EXTRAS1}.tar.gz
mirror://sourceforge/${PN}/${EXTRAS2}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc sparc x86"
IUSE="nls"
RDEPEND=">=x11-libs/gtk+-2
media-libs/libpng
dev-lang/perl
nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
nls? ( sys-devel/gettext )"
src_prepare() {
sed -i \
-e "s:(\"-O6\"):split(' ', \"${CXXFLAGS}\"):" \
configure \
|| die "sed configure failed"
epatch \
"${FILESDIR}"/${P}-as-needed.patch \
"${FILESDIR}"/${P}-gcc44.patch
}
src_configure() {
# not an autoconf script
./configure \
--compiler="${CXX}" \
--prefix="${GAMES_PREFIX}" \
--data-prefix="${GAMES_DATADIR}" \
--man-prefix="/usr/share/man" \
$(use_enable nls) || die
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
dodoc README AUTHORS ChangeLog TODO Documentation/*.txt
newicon icon-eboard.xpm ${PN}.xpm
make_desktop_entry ${PN} ${PN} ${PN}
cd "${WORKDIR}"/${EXTRAS1}
insinto "${GAMES_DATADIR}"/${PN}
doins *.png *.wav || die "doins failed (extra1)"
newins extras1.conf themeconf.extras1 || die "newins failed (extra1)"
newdoc ChangeLog Changelog.extras
newdoc README README.extras
dodoc CREDITS
cd "${WORKDIR}"/${EXTRAS2}
doins *.png *.wav || die "doins failed (extra2)"
newins extras2.conf themeconf.extras2 || die "newins failed (extra2)"
prepgamesdirs
}
|
GitWeb
