blob: e86bfebd31168b0bc128af44d96e9e141a38b08d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/arts-3.5.2.ebuild,v 1.2 2006/03/23 01:47:42 flameeyes Exp $
inherit kde flag-o-matic eutils
set-kdedir 3.5
MY_PV=1.5.2
S=${WORKDIR}/${PN}-${MY_PV}
DESCRIPTION="aRts, the KDE sound (and all-around multimedia) server/output manager"
HOMEPAGE="http://multimedia.kde.org/"
SRC_URI="mirror://kde/stable/${PV}/src/${PN}-${MY_PV}.tar.bz2"
#SRC_URI="mirror://kde/stable/3.5/src/${PN}-${MY_PV}.tar.bz2"
LICENSE="GPL-2 LGPL-2"
SLOT="3.5"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa esd artswrappersuid jack mp3 nas vorbis"
RDEPEND="$(qt_min_version 3.3)
>=dev-libs/glib-2
alsa? ( media-libs/alsa-lib )
vorbis? ( media-libs/libogg
media-libs/libvorbis )
esd? ( media-sound/esound )
jack? ( >=media-sound/jack-audio-connection-kit-0.90 )
mp3? ( media-libs/libmad )
nas? ( media-libs/nas )
media-libs/audiofile"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
PATCHES="${FILESDIR}/arts-1.3.2-alsa-bigendian.patch
${FILESDIR}/arts-1.5.0-bindnow.patch"
src_unpack() {
kde_src_unpack
# Alternative to arts-1.4-mcopidl.patch, make sure that flags are supported
# before trying to use them, for non-GCC, vanilla GCC or GCC 4.1 compilers
local nosspflags
nosspflags="$(test-flags -fno-stack-protector -fno-stack-protector-all)"
sed -i -e "s:KDE_CXXFLAGS =\(.*\):KDE_CXXFLAGS = \1 ${nosspflags}:" \
${S}/mcopidl/Makefile.am
# Fix libao/gaim problems with aRTs. See bug #116290.
epatch "${FILESDIR}/arts-1.5.0-check_tmp_dir.patch"
}
src_compile() {
myconf="$(use_enable alsa) $(use_enable vorbis)
$(use_enable mp3 libmad) $(use_with jack)
$(use_with esd) $(use_with nas)
--with-audiofile --without-mas"
#fix bug 13453
filter-flags -foptimize-sibling-calls
# breaks otherwise <gustavoz>
use sparc && export CFLAGS="-O1" && export CXXFLAGS="-O1"
export BINDNOW_FLAGS="$(bindnow-flags)"
kde_src_compile
}
src_install() {
kde_src_install
# moved here from kdelibs so that when arts is installed
# without kdelibs it's still in the path.
# List all the multilib libdirs
local libdirs
for libdir in $(get_all_libdirs); do
libdirs="${libdirs}:${PREFIX}/${libdir}"
done
dodir /etc/env.d
echo "PATH=${PREFIX}/bin
ROOTPATH=${PREFIX}/sbin:${PREFIX}/bin
LDPATH=${libdirs:1}
CONFIG_PROTECT=\"${PREFIX}/share/config ${PREFIX}/env ${PREFIX}/shutdown\"" > ${D}/etc/env.d/45kdepaths-3.5 # number goes down with version upgrade
# used for realtime priority, but off by default as it is a security hazard
use artswrappersuid && chmod u+s ${D}/${PREFIX}/bin/artswrapper
}
pkg_postinst() {
if ! use artswrappersuid ; then
einfo "Run chmod u+s ${PREFIX}/bin/artswrapper to let artsd use realtime priority"
einfo "and so avoid possible skips in sound. However, on untrusted systems this"
einfo "creates the possibility of a DoS attack that'll use 100% cpu at realtime"
einfo "priority, and so is off by default. See bug #7883."
einfo "Or, you can set the local artswrappersuid USE flag to make the ebuild do this."
fi
}
|
GitWeb