blob: 7ec0cbc7c46d3b54d8ed8c7c994abf6cce337216 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/rhythmbox/rhythmbox-2.99.1.ebuild,v 1.2 2013/08/30 22:46:48 eva Exp $
EAPI="5"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"
inherit eutils gnome2 python-single-r1 multilib virtualx
DESCRIPTION="Music management and playback software for GNOME"
HOMEPAGE="http://projects.gnome.org/rhythmbox/"
LICENSE="GPL-2"
SLOT="0"
IUSE="cdr clutter daap dbus html ipod libnotify libsecret lirc mtp nsplugin +python test +udev upnp-av webkit zeitgeist"
# vala
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
REQUIRED_USE="
ipod? ( udev )
mtp? ( udev )
dbus? ( python )
webkit? ( python )"
# FIXME: double check what to do with fm-radio plugin
COMMON_DEPEND="
>=dev-libs/glib-2.34:2
>=dev-libs/libxml2-2.7.8:2
>=x11-libs/gtk+-3.6.0:3[introspection]
>=x11-libs/gdk-pixbuf-2.18.0:2
>=dev-libs/gobject-introspection-0.10.0
>=dev-libs/libpeas-0.7.3[gtk,python?]
>=dev-libs/totem-pl-parser-3.2
>=net-libs/libsoup-gnome-2.26:2.4
media-libs/gst-plugins-base:1.0[introspection]
media-libs/gstreamer:1.0[introspection]
>=sys-libs/tdb-1.2.6
dev-libs/json-glib
clutter? (
>=media-libs/clutter-1.8:1.0
media-libs/clutter-gst:2.0
>=media-libs/clutter-gtk-1.0:1.0
>=x11-libs/mx-1.0.1:1.0 )
cdr? ( >=app-cdr/brasero-2.91.90 )
daap? ( >=net-libs/libdmapsharing-2.9.16:3.0 )
html? ( >=net-libs/webkit-gtk-1.3.9:3 )
libnotify? ( >=x11-libs/libnotify-0.7.0 )
libsecret? ( >=app-crypt/libsecret-0.14 )
lirc? ( app-misc/lirc )
python? ( >=dev-python/pygobject-3:3[${PYTHON_USEDEP}] )
udev? (
virtual/udev[gudev]
ipod? ( >=media-libs/libgpod-0.7.92[udev] )
mtp? ( >=media-libs/libmtp-0.3 ) )
zeitgeist? ( gnome-extra/zeitgeist )
"
RDEPEND="${COMMON_DEPEND}
media-plugins/gst-plugins-soup:1.0
media-plugins/gst-plugins-libmms:1.0
|| (
media-plugins/gst-plugins-cdparanoia:1.0
media-plugins/gst-plugins-cdio:1.0 )
media-plugins/gst-plugins-meta:1.0
media-plugins/gst-plugins-taglib:1.0
x11-themes/gnome-icon-theme-symbolic
upnp-av? (
>=media-libs/grilo-0.2:0.2
>=media-plugins/grilo-plugins-0.2:0.2[upnp-av] )
python? (
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
dbus? ( sys-apps/dbus )
webkit? (
dev-python/mako[${PYTHON_USEDEP}]
>=net-libs/webkit-gtk-1.3.9:3[introspection] ) )
"
DEPEND="${COMMON_DEPEND}
app-text/scrollkeeper
app-text/yelp-tools
>=dev-util/gtk-doc-am-1.4
>=dev-util/intltool-0.35
virtual/pkgconfig
test? ( dev-libs/check )"
# vala? ( >=dev-lang/vala-0.9.4:0.12 )
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
DOCS="AUTHORS ChangeLog DOCUMENTERS INTERNALS \
MAINTAINERS MAINTAINERS.old NEWS README THANKS"
rm -v lib/rb-marshal.{c,h} || die
gnome2_src_prepare
}
src_configure() {
# FIXME: bug???
export GST_INSPECT=/bin/true
# --enable-vala just installs the sample vala plugin, and the configure
# checks are broken, so don't enable it
gnome2_src_configure \
MOZILLA_PLUGINDIR=/usr/$(get_libdir)/nsbrowser/plugins \
VALAC=$(type -P valac-0.14) \
--enable-mmkeys \
--disable-more-warnings \
--disable-static \
--disable-vala \
--without-hal \
$(use_enable clutter visualizer) \
$(use_enable daap) \
$(use_enable libnotify) \
$(use_enable lirc) \
$(use_enable nsplugin browser-plugin) \
$(use_enable python) \
$(use_enable upnp-av grilo) \
$(use_with cdr brasero) \
$(use_with html webkit) \
$(use_with ipod) \
$(use_with libsecret) \
$(use_with mtp) \
$(use_with udev gudev)
}
src_test() {
unset SESSION_MANAGER
unset DBUS_SESSION_BUS_ADDRESS
Xemake check
}
|
GitWeb