media-sound/tomahawk/tomahawk-0.6.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/tomahawk/tomahawk-0.6.1.ebuild,v 1.6 2014/01/20 10:37:11 kensington Exp $

EAPI=5

QT_MINIMAL="4.7.0"

CMAKE_MIN_VERSION="2.8.6"

if [[ ${PV} != *9999* ]]; then
	SRC_URI="http://download.tomahawk-player.org/${P}.tar.bz2"
	KEYWORDS="~amd64 ~x86"
else
	GIT_ECLASS="git-2"
	EGIT_REPO_URI="git://github.com/tomahawk-player/${PN}.git"
	KEYWORDS=""
fi

inherit cmake-utils qt4-r2 ${GIT_ECLASS}

DESCRIPTION="Qt playdar social music player"
HOMEPAGE="http://tomahawk-player.org/"

LICENSE="GPL-3 BSD"
SLOT="0"
IUSE="debug jabber twitter"

DEPEND="
	app-crypt/qca:2
	>=dev-cpp/clucene-2.3.3.4
	>=dev-libs/boost-1.41
	>=dev-libs/libattica-0.4.0[qt4]
	dev-libs/qjson
	dev-libs/quazip
	>=dev-qt/qtcore-${QT_MINIMAL}:4
	>=dev-qt/qtdbus-${QT_MINIMAL}:4
	|| ( ( >=dev-qt/qtgui-4.8.5:4 dev-qt/designer:4 ) <dev-qt/qtgui-4.8.5:4 )
	>=dev-qt/qtsql-${QT_MINIMAL}:4[sqlite]
	>=dev-qt/qtsvg-${QT_MINIMAL}:4
	>=dev-qt/qtwebkit-${QT_MINIMAL}:4
	>=media-libs/liblastfm-1.0.1
	>=media-libs/libechonest-2.0.1
	>=media-libs/phonon-4.5.0
	>=media-libs/taglib-1.6.0
	x11-libs/libX11
	jabber? ( >=net-libs/jreen-1.1.1 )
	twitter? ( net-libs/qtweetlib )
"
RDEPEND="${DEPEND}
	app-crypt/qca-ossl
"
DOCS=( AUTHORS ChangeLog README.md )

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_with jabber Jreen)
		$(cmake-utils_use_with twitter QTweetLib)
	)

	if [[ ${PV} != *9999* ]]; then
		mycmakeargs+=( -DBUILD_RELEASE=ON )
	fi

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install
}