media-sound/wildmidi/wildmidi-0.2.3.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/wildmidi-0.2.3.5.ebuild,v 1.8 2013/02/16 08:11:46 pacho Exp $

EAPI=5
inherit base autotools readme.gentoo

DESCRIPTION="Midi processing library and a midi player using the gus patch set"
HOMEPAGE="http://wildmidi.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="amd64 arm hppa ppc ppc64 x86"
IUSE="alsa debug"

DEPEND="alsa? ( media-libs/alsa-lib )"
RDEPEND="${DEPEND}
	media-sound/timidity-freepats"

src_prepare() {
	DOC_CONTENTS="${PN} is using timidity-freepats for midi playback.
		A default configuration file was placed on /etc/${PN}.cfg.
		For more information please read the ${PN}.cfg manpage."

	# Workaround for parallel make
	sed -i -e "/^wildmidi_libs/s:=.*:= libWildMidi.la:" "${S}"/src/Makefile.am || die
	eautoreconf
}

src_configure() {
	econf \
		--disable-werror \
		$(use_enable debug) \
		$(use alsa || echo --with-oss)
}

src_install() {
	base_src_install
	find "${D}" -name '*.la' -exec rm -f {} +
	insinto /etc
	doins "${FILESDIR}"/${PN}.cfg
	readme.gentoo_create_doc
}