net-dns/dnssec-tools/dnssec-tools-1.12.2-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/dnssec-tools/dnssec-tools-1.12.2-r2.ebuild,v 1.1 2012/06/18 15:28:26 flameeyes Exp $

EAPI=4

inherit qt4-r2

DESCRIPTION="tools to ease the deployment of DNSSEC related technologies"
HOMEPAGE="http://www.dnssec-tools.org/"
SRC_URI="http://www.dnssec-tools.org/download/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ipv6 static-libs threads"

RDEPEND="dev-lang/perl
	dev-libs/openssl
	dev-perl/Getopt-GUI-Long
	dev-perl/GraphViz
	dev-perl/MailTools
	dev-perl/Net-DNS
	dev-perl/XML-Simple"
DEPEND="${RDEPEND}"

src_prepare() {
	sed -e '/^maninstall:/,+3s:$(MKPATH) $(mandir)/$(man1dir):$(MKPATH) $(DESTDIR)/$(mandir)/$(man1dir):' \
		-i Makefile.in || die

	rm -r validator/apps/{dnssec-{check,nodes,system-tray},lookup}
}

src_configure() {
	econf \
		--disable-bind-checks \
		--with-dlv \
		--with-nsec3 \
		--with-gnu-ld \
		--with-validator \
		--with-perl-build-args=INSTALLDIRS=vendor \
		$(use_with ipv6) \
		$(use_enable static-libs static) \
		$(use_with threads)
}

src_compile() {
	my_prognames="VALIDATOR=dnssec-validate
		GETHOST=dnssec-gethost
		GETADDR=dnssec-getaddr
		GETRRSET=dnssec-getrrset
		GETQUERY=dnssec-getquery
		GETNAME=dnssec-getname
		CHECK_CONF=dnssec-libval_check_conf
		SRES_TEST=dnssec-libsres_test"
	emake $my_prognames
}

src_install() {
	emake DESTDIR="${D}" $my_prognames install
	if ! use static-libs ; then
		find "${D}" -name "*.la" -delete || die
	fi
}

pkg_postinst() {
	einfo
	elog "Please run 'dtinitconf' in order to set up the required"
	elog "/etc/dnssec-tools/dnssec-tools.conf file"
	einfo
}