net-wireless/ndiswrapper/ndiswrapper-1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/ndiswrapper/ndiswrapper-1.1.ebuild,v 1.1 2005/03/05 22:40:55 cardoe Exp $

inherit linux-mod eutils

DESCRIPTION="Wrapper for using Windows drivers for some wireless cards"
HOMEPAGE="http://ndiswrapper.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~x86 ~amd64"

IUSE="debug 4kstacks"
DEPEND="sys-apps/pciutils"
S=${WORKDIR}/${P}

if use !4kstacks
then
	CONFIG_CHECK="!4KSTACKS"
fi

#4KSTACKS_ERROR="CONFIG_4KSTACKS should not be set.\nIf you feel really confident that 4K Stacks will work for you, add '4kstacks' to your USE flags. But don't expect any support from Gentoo."

CONFIG_CHECK="${CONFIG_CHECK} NET_RADIO"

MODULE_NAMES="ndiswrapper(misc:${S}/driver)"
BUILD_PARAMS="KSRC=${ROOT}${KV_DIR} KVERS=${KV_MAJOR}${KV_MINOR}"
BUILD_TARGETS="all"
MODULESD_NDISWRAPPER_ALIASES=("wlan0 ndiswrapper")

src_unpack() {
	unpack ${A}

	if grep '# CONFIG_SOFTWARE_SUSPEND2 is not set' ${ROOT}${KV_DIR}/.config
	then
		eerror "You have a kernel patched with Software Suspend 2 (swsusp2)"
		eerror "but don't have it enabled. You must remove the patch or"
		eerror "enable Software Suspend 2 (swsusp2)."
		eerror "http://bugs.gentoo.org/show_bug.cgi?id=74864"
		die "Please fix your kernel"
	fi

	convert_to_m ${S}/driver/Makefile
}

src_compile() {
	# Enable verbose debugging information
	use debug && export DEBUG=3

	cd utils
	emake || die "Compile of utils failed!"

	linux-mod_src_compile

}

src_install() {
	dosbin utils/ndiswrapper
	dosbin utils/ndiswrapper-buginfo

	into /
	dosbin utils/loadndisdriver

	dodoc README INSTALL AUTHORS ChangeLog
	doman ndiswrapper.8

	keepdir /etc/ndiswrapper

	linux-mod_src_install
}

pkg_postinst() {
	linux-mod_pkg_postinst
	echo
	einfo "ndiswrapper requires .inf and .sys files from a Windows(tm) driver"
	einfo "to function. Download these to /root for example, then"
	einfo "run 'ndiswrapper -i /root/foo.inf'. After that you can delete them."
	einfo "They will be copied to the proper location."
	einfo "Once done, please run 'update-modules'."
	echo
	einfo "check http://ndiswrapper.sf.net/phpwiki/index.php/List for drivers"
	I=`lspci -n | egrep 'Class (0280|0200):' |  cut -d' ' -f4`
	einfo "Look for the following on that page for your driver:"
	einfo ${I}
	echo
	einfo "Please have a look at http://ndiswrapper.sourceforge.net/wiki/"
	einfo "for the FAQ, HowTos, Tips, Configuration, and installation"
	einfo "information."
	echo
	ewarn "IF UPGRADING FROM PRE-1.0!!!"
	ewarn "You MUST re-install your Windows drivers."
	ewarn "Best way to do this is to run the following commands"
	ewarn "mv /etc/ndiswrapper/{driver} /tmp"
	ewarn "ndiswrapper -i /tmp/{driver}/{driver}.inf"
	ebeep
	ebeep
	ebeep
}