sci-libs/cblas-reference/cblas-reference-20030223.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/cblas-reference/cblas-reference-20030223.ebuild,v 1.2 2006/03/27 14:41:56 markusle Exp $

inherit eutils fortran multilib

MyPN="${PN/-reference/}"

DESCRIPTION="C interface to the BLAS"
LICENSE="public-domain"
HOMEPAGE="http://www.netlib.org/blas/"
SRC_URI="http://www.netlib.org/blas/blast-forum/${MyPN}.tgz"

SLOT="0"
IUSE=""
KEYWORDS="~x86"

DEPEND="sys-devel/libtool
		virtual/blas
		sci-libs/blas-config"

FORTRAN="gfortran g77 ifc"

S="${WORKDIR}/CBLAS"

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}"/cblas-gentoo.patch
}

src_compile() {
	TOP_PATH="${DESTTREE}/$(get_libdir)/blas"
	RPATH="${TOP_PATH}/reference"
	cd "${S}"/src

	make all FC="libtool --mode=compile --tag=F77 ${FORTRANC}" \
		FFLAGS="${FFLAGS}" CC="libtool --mode=compile --tag=CC gcc" \
		CFLAGS="${CFLAGS} -DADD_" || die "make failed"

	libtool --mode=link --tag=F77 ${FORTRANC} -o libcblas.la *.lo \
		-rpath "${RPATH}" || die "failed to link static libraries"
	libtool --mode=link --tag=F77 ${FORTRANC} -shared *.lo \
		-Wl,-soname -Wl,libcblas.so.0 -o libcblas.so.0.0.0 || \
		die "failed to link shared libraries"
}

src_install() {
	dodir "${RPATH}" || die "failed to create lib directory"

	cd "${S}"/src

	libtool --mode=install install -s libcblas.la "${D}/${RPATH}"\
		|| die "failed to install static library"

	insinto "${DESTTREE}"/include/${PN}
	doins cblas_f77.h cblas.h || die "failed to install header files"

	dodoc "${S}"/README || die "failed to install docs"

	insinto "${TOP_PATH}"
	doins "${FILESDIR}"/c-reference || \
		die "failed to install blas-config file"
}

pkg_postinst() {
	    blas-config c-reference
}