sys-fs/multipath-tools/multipath-tools-0.4.6.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/multipath-tools/multipath-tools-0.4.6.1.ebuild,v 1.1 2006/01/26 21:41:10 seemant Exp $

inherit toolchain-funcs

DESCRIPTION="Device mapper target autoconfig."
HOMEPAGE="http://christophe.varoqui.free.fr/wiki/wakka.php?wiki=Home"
SRC_URI="http://christophe.varoqui.free.fr/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

IUSE=""

RDEPEND=">=sys-fs/device-mapper-1.00.19
	sys-fs/udev
	sys-fs/sysfsutils"

DEPEND="${RDEPEND}"

src_unpack() {
	unpack ${A}; cd ${S}
	sed -i -e 's:^bindir.*:bindir = /usr/sbin:' \
		${S}/multipathd/Makefile
	sed -i -e 's:rules.d/.*:rules.d/40-multipath.rules:' \
		${S}/multipath/Makefile
}

src_compile() {
	emake -j1 \
		CC=$(tc-getCC) || die "emake failed"
}

src_install() {
	dodir /sbin /usr/share/man/man8
	make DESTDIR=${D} install || die "install failed"

	insinto /etc
	newins ${S}/multipath.conf.annotated multipath.conf
	fperms 644 /etc/udev/rules.d/40-multipath.rules
	newinitd ${FILESDIR}/rc-multipathd multipathd

	# The dev.d script was previously wrong and is now removed (the udev rules
	# file does the job instead), but it won't be removed from live systems due
	# to cfgprotect.
	# This should help out a little...
	if [[ -e "${ROOT}"/etc/dev.d/block/multipath.dev ]] ; then
		mkdir -p "${D}"/etc/dev.d/block
		echo "# Please delete this file. It is obsoleted by /etc/udev/rules.d/40-multipath.rules" \
			> "${D}"/etc/dev.d/block/multipath.dev
	fi

	dodoc AUTHOR COPYING ChangeLog FAQ README TODO
	docinto dmadm; dodoc README
	docinto kpartx; dodoc ChangeLog README
}