x11-misc/gigolo/gigolo-0.3.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/gigolo/gigolo-0.3.2.ebuild,v 1.2 2009/08/23 03:30:32 darkside Exp $

EAPI="2"
inherit xfconf multilib

DESCRIPTION="a frontend to easily manage connections to remote filesystems using
GIO/GVfs"
HOMEPAGE="http://www.uvena.de/gigolo/index.html http://goodies.xfce.org/projects/applications/gigolo"
SRC_URI="http://files.uvena.de/gigolo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=x11-libs/gtk+-2.12:2
	>=dev-libs/glib-2.16:2"
RDEPEND="${DEPEND}"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README TODO"
}

src_configure() {
	./waf --prefix="/usr" --libdir="/usr/$(get_libdir)" configure \
		|| die "./waf configure failed"
}

src_compile() {
	# Build takes -jX, but not -lX so cannot use $MAKEOPTS
	NUMJOBS=$(sed -e 's/.*\(\-j[ 0-9]\+\) .*/\1/; s/--jobs=\?/-j/' <<< ${MAKEOPTS})
	./waf build ${NUMJOBS} || die "./waf build failed"
}

src_install() {
	./waf --destdir="${D}" install || die "./waf install failed"

	# process docs
	dodoc ${DOCS} || die "dodoc failed"
	rm -rf "${D}"/usr/share/doc/${PN}
}