dev-java/eclipse-jetty-security/eclipse-jetty-security-8.1.10.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="5"

JAVA_PKG_IUSE="test"

inherit java-pkg-2 java-ant-2 java-osgi

DESCRIPTION="Eclipse Jetty Security"
HOMEPAGE="http://www.eclipse.org/jetty/"
LICENSE="Apache-2.0 EPL-1.0"

BUILD_DATE="20130312"

MY_PV="${PV}.v${BUILD_DATE}"
MY_P="${PN/eclipse-/}-${MY_PV}"

SRC_URI="http://repo1.maven.org/maven2/org/eclipse/jetty/${PN/eclipse-/}/${MY_PV}/${MY_P}-sources.jar"
SLOT="8"
KEYWORDS="~amd64 ~x86"

S="${WORKDIR}"

COMMON_DEPEND="dev-java/eclipse-jetty-http:8
	dev-java/eclipse-jetty-server:8
	dev-java/eclipse-jetty-util:8
	java-virtuals/servlet-api:3.0"

DEPEND="${COMMON_DEPEND}
	>=virtual/jdk-1.7
	test? (
		dev-java/ant-junit:0
		dev-java/junit:0
	)"

RDEPEND="${COMMON_DEPEND}
	>=virtual/jre-1.7"

java_prepare() {
	cd "${S}" || die
	cp "${FILESDIR}"/${P}-build.xml build.xml || die
	sed -i 's/manifest=".*"/manifest="META-INF\/MANIFEST.MF"/g' build.xml || die
	sed -i 's/\(<mkdir dir="${maven.build.outputDir}"\/>\)/\1<javac srcdir="." destdir="${maven.build.outputDir}" \/>/g' build.xml || die
}

EANT_GENTOO_CLASSPATH="eclipse-jetty-util-8,eclipse-jetty-http-8,eclipse-jetty-server-8,servlet-api-3.0"
EANT_TEST_GENTOO_CLASSPATH="junit"
JAVA_ANT_REWRITE_CLASSPATH="true"

src_test() {
	java-pkg-2_src_test
}

src_install() {
	java-osgi_newjar-fromfile target/${MY_P}.jar META-INF/MANIFEST.MF org.eclipse.jetty.security
}