1 files changed, 67 insertions, 0 deletions
diff --git a/dev-libs/gjs/gjs-1.33.2.ebuild b/dev-libs/gjs/gjs-1.33.2.ebuild
new file mode 100644
index 0000000..7bec3ac
--- /dev/null
+++ b/dev-libs/gjs/gjs-1.33.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gjs/gjs-1.32.0.ebuild,v 1.3 2012/05/28 00:19:48 mattst88 Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="2"
+
+inherit gnome2 pax-utils python virtualx
+
+DESCRIPTION="Javascript bindings for GNOME"
+HOMEPAGE="http://live.gnome.org/Gjs"
+
+LICENSE="MIT MPL-1.1 LGPL-2 GPL-2"
+SLOT="0"
+IUSE="examples test"
+KEYWORDS="~alpha ~amd64 ~x86"
+
+RDEPEND=">=dev-libs/glib-2.31:2
+	>=dev-libs/gobject-introspection-1.31.22
+
+	dev-libs/dbus-glib
+	sys-libs/readline
+	x11-libs/cairo
+	>=dev-lang/spidermonkey-1.8.5"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+pkg_setup() {
+	# AUTHORS, ChangeLog are empty
+	DOCS="NEWS README"
+	# FIXME: add systemtap/dtrace support, like in glib:2
+	# FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
+	# XXX: Do NOT enable coverage, completely useless for portage installs
+	G2CONF="${G2CONF}
+		--disable-systemtap
+		--disable-dtrace
+		--disable-coverage"
+
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	python_convert_shebangs 2 "${S}"/scripts/make-tests
+}
+
+src_test() {
+	# Tests need dbus
+	Xemake check
+}
+
+src_install() {
+	# installation sometimes fails in parallel
+	gnome2_src_install -j1
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins ${S}/examples/*
+	fi
+
+	# Required for gjs-console to run correctly on PaX systems
+	pax-mark mr "${ED}/usr/bin/gjs-console"
+}