kde-plasma/kinfocenter: 5.27.6 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/kde-plasma/kinfocenter/Manifest b/kde-plasma/kinfocenter/Manifest
index c5bffaee3e..c7fc2a5b75 100644
--- a/kde-plasma/kinfocenter/Manifest
+++ b/kde-plasma/kinfocenter/Manifest
@@ -1 +1,2 @@
 DIST glogo-small.png 24583 BLAKE2B 0af2ceae708e56f217120e5d8b880fb71401e3761ab26c4af5e74c0622368aa4e34b05160fae15fbfbbc832077810ab5c1e424826632748299fd22997cbe665c SHA512 648be463ec3812a2edcdab54d7a230bf2bd7e6895f4ffe72321d8fca28a5e1e0980f6e3b9a32f369c8369943ceb802a65a94b9dad820dcf2c81d4581d814cb48
+DIST kinfocenter-5.27.6.tar.xz 1015920 BLAKE2B cd26912eb20675e13f1fb8dc2456f4c57b9467dddca5d50a466d4d4664d0a062005e38c77dbdd7be86434b87b2d9c18b4c1223ad249975ac528c9fb93409a166 SHA512 2f4eea953f2c6d53ae3a0f38265fac71d68df9dd52261e63c8b2f8cd9d811b31b40a94e9230a041186a0cdf86726abc7504f32534bf2fc797739bc32dd9c9bdf
diff --git a/kde-plasma/kinfocenter/kinfocenter-5.27.6.ebuild b/kde-plasma/kinfocenter/kinfocenter-5.27.6.ebuild
new file mode 100644
index 0000000000..3fb4fd8a90
--- /dev/null
+++ b/kde-plasma/kinfocenter/kinfocenter-5.27.6.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org optfeature
+
+DESCRIPTION="Utility providing information about the computer hardware"
+HOMEPAGE="https://userbase.kde.org/KInfoCenter"
+SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gles2-only usb"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5[gles2-only=]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	gles2-only? ( media-libs/mesa[gles2] )
+	usb? ( virtual/libusb:1 )
+"
+RDEPEND="${DEPEND}
+	dev-qt/qdbus:*
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+	>=kde-plasma/systemsettings-${PVCUT}:5
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package usb USB1)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# TODO: Make this fully obsolete by /etc/os-release
+	insinto /etc/xdg
+	doins "${FILESDIR}"/kcm-about-distrorc
+
+	insinto /usr/share/${PN}
+	doins "${DISTDIR}"/glogo-small.png
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "NFS information module" net-fs/nfs-utils
+		optfeature "Samba status information module" net-fs/samba
+		optfeature "Vulkan graphics API information module" dev-util/vulkan-tools
+		optfeature "advanced CPU information module" sys-apps/util-linux
+	fi
+	optfeature "Wayland information module" app-misc/wayland-utils
+	optfeature "Firmware security module" "app-text/aha sys-apps/fwupd"
+	optfeature "OpenGL information module" x11-apps/mesa-progs
+	optfeature "PCI devices information module" sys-apps/pciutils
+	optfeature "X Server information module" x11-apps/xdpyinfo
+	ecm_pkg_postinst
+}