www-client/falkon: 23.08.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/www-client/falkon/Manifest b/www-client/falkon/Manifest
index 46f7c5a0e6..ff63be6420 100644
--- a/www-client/falkon/Manifest
+++ b/www-client/falkon/Manifest
@@ -1 +1,2 @@
+DIST falkon-23.08.5.tar.xz 2574364 BLAKE2B 9090263ee1e9a76cf9efebf6f3c8b5d0ca25a907f467ebe5adff6d54e71c79aa982317094ea354fb4fa898244b119b73640fc92ae301f95fe78551d3e84921a9 SHA512 215e2a4ff551aa6d3fab0317d2b2b823b7fee4c1f6a653118d00f3def9ebb037931e8cd81f33785a44c8aa8910e00fbda884c1cfcdb61190544d1e6c8396acf8
 DIST falkon-24.01.95.tar.xz 2582856 BLAKE2B 418d1765b0c835490dda3c550b868d8d67dbd2637a955f609640658f729a25f8b3f13fda4a4e4b32892ba55c91b6e03a4dd078a56645df2ac0a988037ba17e44 SHA512 5965f8b2e713b418800cbd050acbdc1806ab8ad284c585b85d5609118a98e3612582fe72e55b88d9596d19c6df974fa588adff04b006138d214c979677e02fd5
diff --git a/www-client/falkon/falkon-23.08.5.ebuild b/www-client/falkon/falkon-23.08.5.ebuild
new file mode 100644
index 0000000000..303e1991c2
--- /dev/null
+++ b/www-client/falkon/falkon-23.08.5.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+PYTHON_COMPAT=( python3_{10..11} )
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwebchannel-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	virtual/libintl
+	dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:5
+		>=kde-frameworks/kcrash-${KFMIN}:5
+		>=kde-frameworks/kio-${KFMIN}:5
+		>=kde-frameworks/kjobwidgets-${KFMIN}:5
+		>=kde-frameworks/kwallet-${KFMIN}:5
+		>=kde-frameworks/purpose-${KFMIN}:5
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
+			>=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-23.07.80-python3.patch" )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF5Wallet)
+		$(cmake_use_find_package kde KF5KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}