Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
aboutsummaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat
-rw-r--r--dev-python/cadquery-ocp/Manifest1
-rw-r--r--dev-python/cadquery-ocp/cadquery-ocp-7.5.3.0.ebuild197
-rw-r--r--dev-python/cadquery-ocp/metadata.xml11
-rw-r--r--dev-python/cadquery-pywrap/Manifest1
-rw-r--r--dev-python/cadquery-pywrap/cadquery-pywrap-7.5.3_rc20220113.ebuild63
-rw-r--r--dev-python/cadquery-pywrap/metadata.xml12
-rw-r--r--dev-python/cadquery/Manifest1
-rw-r--r--dev-python/cadquery/cadquery-2.2_rc20220506.ebuild60
-rw-r--r--dev-python/cadquery/metadata.xml12
-rw-r--r--profiles/package.mask7
10 files changed, 0 insertions, 365 deletions
diff --git a/dev-python/cadquery-ocp/Manifest b/dev-python/cadquery-ocp/Manifest
deleted file mode 100644
index 9b34bca41..000000000
--- a/dev-python/cadquery-ocp/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST cadquery-ocp-7.5.3.0.tar.gz 5571719 BLAKE2B ba31d7ae2f54e2f4c17f0914cab1299b91254a3fab7d07f18b2d698ce6e47e9ea174e449e18971197b39f08fa755c4d16d8cba24f894372f5bd515ec6686935e SHA512 b89dc91f224ee87e288bd7e3a10cb3b2c6559e2b36c24aac2f675fb05ecda755b723721122a7e58d87ba4253024892795369b1e747fb77684c739d01d516d1a2
diff --git a/dev-python/cadquery-ocp/cadquery-ocp-7.5.3.0.ebuild b/dev-python/cadquery-ocp/cadquery-ocp-7.5.3.0.ebuild
deleted file mode 100644
index 8a97782bd..000000000
--- a/dev-python/cadquery-ocp/cadquery-ocp-7.5.3.0.ebuild
+++ /dev/null
@@ -1,197 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_10 )
-
-# OCP uses "python-single-r1" only because VTK uses "python-single-r1".
-inherit check-reqs cmake llvm multiprocessing python-single-r1 toolchain-funcs
-
-MY_PN=OCP
-MY_PV="${PV//_/-}"
-MY_P="${MY_PN}-${MY_PV}"
-OCCT_PV=$(ver_cut 1-3)
-
-DESCRIPTION="Python wrapper for OCCT generated using pywrap"
-HOMEPAGE="https://github.com/CadQuery/OCP"
-SRC_URI="https://github.com/CadQuery/OCP/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-# Hard masking due to opencascade slot 0/7.5 having been removed from ::gentoo in ff9032e688571dde15e9d36cebedf5a247ded1b8
-#KEYWORDS="~amd64 ~x86"
-KEYWORDS=""
-SLOT="0"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-# CMake and VTK requirements derive from the "OCP/CMakeLists.txt" file
-# generated by the src_prepare() phase. OCP currently requires opencascade
-# (OCCT) to be built with "-DUSE_GLES2=OFF" and thus "-gles2". See also:
-# https://github.com/CadQuery/OCP/issues/46#issuecomment-808920994
-BDEPEND="
- >=dev-libs/lief-0.11.5[python,${PYTHON_SINGLE_USEDEP}]
- >=dev-util/cmake-3.16
-"
-RDEPEND="
- ${PYTHON_DEPS}
- sci-libs/opencascade:0/7.5[json,tbb,vtk]
- >=sci-libs/vtk-9.0.0[python,${PYTHON_SINGLE_USEDEP}]
-"
-DEPEND="${RDEPEND}
- $(python_gen_cond_dep '
- >=dev-python/cadquery-pywrap-'${OCCT_PV}'_rc0[${PYTHON_USEDEP}]')
-"
-
-S="${WORKDIR}/${MY_P}"
-
-# The source "OCP/CMakeLists.txt" file is output by "bindgen" in src_prepare().
-CMAKE_IN_SOURCE_BUILD=True
-
-# Ensure the path returned by get_llvm_prefix() contains clang.
-llvm_check_deps() {
- has_version -r "sys-devel/clang:${LLVM_SLOT}"
-}
-
-cadquery-ocp_check_reqs() {
- CHECKREQS_DISK_BUILD=1300M check-reqs_pkg_${EBUILD_PHASE}
-}
-
-pkg_pretend() {
- cadquery-ocp_check_reqs
-}
-
-pkg_setup() {
- cadquery-ocp_check_reqs
- llvm_pkg_setup
- python-single-r1_pkg_setup
-}
-
-# OCP currently requires manual configuration, compilation, and installation
-# loosely inspired by the conda-specific "build-bindings-job.yml" file.
-#
-# Note that the cmake_src_prepare() function called below handles user patches.
-src_prepare() {
- # Most recently installed version of Clang.
- local _CLANG_VERSION="$(CPP=clang clang-fullversion)"
-
- # Most recently installed version (excluding trailing patch) of VTK.
- local _VTK_VERSION="$(best_version -r sci-libs/vtk)"
- _VTK_VERSION="$(ver_cut 1-2 "${_VTK_VERSION##sci-libs/vtk}")"
-
- # Absolute dirname of the most recently installed Clang include directory,
- # mimicing similar logic in the "dev-python/shiboken2" ebuild. See also:
- # https://bugs.gentoo.org/619490
- local _CLANG_INCLUDE_DIR="${EPREFIX}/usr/lib/clang/${_CLANG_VERSION}/include"
-
- # Absolute filename of the most recently installed Clang shared library.
- local _CLANG_LIB_FILE="$(get_llvm_prefix)/lib64/libclang.so"
-
- # Absolute dirname of OCCT's include and shared library directories.
- local _OCCT_INCLUDE_DIR="${EPREFIX}/usr/include/opencascade"
- local _OCCT_LIB_DIR="${EPREFIX}/usr/lib64/opencascade"
-
- # Absolute dirname of a temporary directory to store symbol tables for this
- # OCCT version dumped below by the "dump_symbols.py" script.
- local _OCCT_DUMP_SYMBOLS_ROOT_DIR="${T}/dump_symbols"
- local _OCCT_DUMP_SYMBOLS_DIR="${_OCCT_DUMP_SYMBOLS_ROOT_DIR}/lib_linux"
-
- # Absolute dirname of VTK's include directory,
- local _VTK_INCLUDE_DIR="${EPREFIX}/usr/include/vtk-${_VTK_VERSION}"
-
- # Ensure the above paths exist as a crude sanity test.
- test -d "${_CLANG_INCLUDE_DIR}" || die "${_CLANG_INCLUDE_DIR} not found."
- test -f "${_CLANG_LIB_FILE}" || die "${_CLANG_LIB_FILE} not found."
- test -d "${_OCCT_INCLUDE_DIR}" || die "${_OCCT_INCLUDE_DIR} not found."
- test -d "${_OCCT_LIB_DIR}" || die "${_OCCT_LIB_DIR} not found."
- test -d "${_VTK_INCLUDE_DIR}" || die "${_VTK_INCLUDE_DIR} not found."
-
- # "dev-python/clang-python" atom targeting this Clang version.
- local _CLANG_PYTHON_ATOM="dev-python/clang-python-${_CLANG_VERSION}"
-
- # Ensure "dev-python/clang-python" targets this Clang version.
- has_version -r "=${_CLANG_PYTHON_ATOM}" ||
- die "${_CLANG_PYTHON_ATOM} not installed."
-
- # Remove all vendored paths.
- rm -r conda opencascade pywrap *.dat || die
-
- # Inject a symlink to OCCT's include directory.
- ln -s "${_OCCT_INCLUDE_DIR}" opencascade || die
-
- # Inject a symlink from OCCT's shared library directory into this temporary
- # directory as required by the "dump_symbols.py" script.
- mkdir -p "${_OCCT_DUMP_SYMBOLS_DIR}" || die
- ln -s "${_OCCT_LIB_DIR}" "${_OCCT_DUMP_SYMBOLS_DIR}"/. || die
-
- # Update all hardcoded OCCT shared library versions in "dump_symbols.py".
- sed -i -e 's~\(\.so\.\)[0-9]\+.[0-9]\+.[0-9]\+~\1'${OCCT_PV}'~' \
- dump_symbols.py || die
-
- # Dump (i.e., generate) symbol tables for this OCCT version.
- einfo 'Dumping OCCT symbol tables...'
- ${EPYTHON} dump_symbols.py "${_OCCT_DUMP_SYMBOLS_ROOT_DIR}" || die
-
- # Generate OCCT bindings in the "OCP/" subdirectory.
- einfo 'Building OCP CMake binary tree...'
- ${EPYTHON} -m bindgen \
- --verbose \
- --njobs $(makeopts_jobs) \
- --libclang "${_CLANG_LIB_FILE}" \
- --include "${_CLANG_INCLUDE_DIR}" \
- --include "${_VTK_INCLUDE_DIR}" \
- all ocp.toml || die
-
- # Remove the source "FindOpenCascade.cmake" after generating bindings,
- # which copied that file to the target "OCP/FindOpenCascade.cmake".
- rm FindOpenCascade.cmake || die
-
- #FIXME: Submit an issue recommending upstream replace their
- #non-working "OCP/FindOpenCascade.cmake" file with a standard top-level
- #"CMakeLists.txt" file that finds dependency paths: e.g., via @waebbl
- # find_package(vtk 9 CONFIG REQUIRED)
- # if(TARGET VTK::VTK)
- # get_target_property(VTK_INCLUDE_DIRS VTK::VTK INTERFACE_INCLUDE_DIRECTORIES)
- # endif()
-
- # Replace all hardcoded paths in "OCP/FindOpenCascade.cmake" with
- # standard OCCT paths derived above. That file is both fundamentally
- # broken and useless, as the ${CASROOT} environment variable and
- # "/usr/lib64/cmake/opencascade-${PV}/OpenCASCADEConfig.cmake" file
- # already reliably identify all requisite OpenCASCADE paths. Failure to
- # patch this file results in src_configure() failures resembling:
- # -- Could NOT find OPENCASCADE (missing: OPENCASCADE_LIBRARIES)
- sed -i \
- -e 's~$ENV{CONDA_PREFIX}/include/opencascade\b~'${_OCCT_INCLUDE_DIR}'~' \
- -e 's~$ENV{CONDA_PREFIX}/lib\b~'${_OCCT_LIB_DIR}'~' \
- -e 's~$ENV{CONDA_PREFIX}/Library/\(lib\|include/opencascade\)~~' \
- OCP/FindOpenCascade.cmake || die
-
- # Patch the "OCP/CMakeLists.txt" file generated by "bindgen" above, passed
- # as an absolute path both here and below to minimize eclass issues.
- CMAKE_USE_DIR="${S}/OCP" cmake_src_prepare
-}
-
-src_configure() {
- local mycmakeargs=(
- -B "${S}/OCP.build"
- -DPYTHON_EXECUTABLE="${PYTHON}"
- -Wno-dev
- )
-
- CMAKE_USE_DIR="${S}/OCP" cmake_src_configure
-}
-
-src_compile() {
- CMAKE_USE_DIR="${S}/OCP.build" cmake_src_compile
-}
-
-# OCP currently ships no test suite, so we synthesize a crude import unit test.
-src_test() {
- PYTHONPATH="${S}/OCP.build" ${EPYTHON} -c \
- 'from OCP.gp import gp_Vec, gp_Ax1, gp_Ax3, gp_Pnt, gp_Dir, gp_Trsf, gp_GTrsf, gp, gp_XYZ'
-}
-
-src_install() {
- python_moduleinto .
- python_domodule "${S}/OCP.build/"OCP*.so
-}
diff --git a/dev-python/cadquery-ocp/metadata.xml b/dev-python/cadquery-ocp/metadata.xml
deleted file mode 100644
index a8bf5ee04..000000000
--- a/dev-python/cadquery-ocp/metadata.xml
+++ /dev/null
@@ -1,11 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
- <maintainer type="project">
- <email>sci@gentoo.org</email>
- <name>Gentoo Science Project</name>
- </maintainer>
- <upstream>
- <remote-id type="github">CadQuery/OCP</remote-id>
- </upstream>
-</pkgmetadata>
diff --git a/dev-python/cadquery-pywrap/Manifest b/dev-python/cadquery-pywrap/Manifest
deleted file mode 100644
index 4bccc9e86..000000000
--- a/dev-python/cadquery-pywrap/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST cadquery-pywrap-7.5.3_rc20220113.tar.gz 5584755 BLAKE2B d6585d33eddc34c719f9694322d209969698d6e5c67288a95ad841efbc2347d2cb162d8f3443a4e3373d70b97423485d1535c60713e4cb8ace413d114b852083 SHA512 f0d984b6fa6df3151d9cb612560a5266f98d286b9ab283c4647095dda3da1c54fb102babee4d2db574b695604332bc7576740406907995940eb60635afb614b8
diff --git a/dev-python/cadquery-pywrap/cadquery-pywrap-7.5.3_rc20220113.ebuild b/dev-python/cadquery-pywrap/cadquery-pywrap-7.5.3_rc20220113.ebuild
deleted file mode 100644
index 7a3b772f3..000000000
--- a/dev-python/cadquery-pywrap/cadquery-pywrap-7.5.3_rc20220113.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_10 )
-
-inherit llvm distutils-r1
-
-DESCRIPTION="C++ binding generator based on libclang and pybind11"
-HOMEPAGE="https://github.com/CadQuery/pywrap"
-
-#FIXME: Uncomment on bumping to the next stable release.
-# MY_PN=occt
-# MY_PV=$(ver_cut 1-2)
-# MY_P="${MY_PN}${MY_PV}"
-# SRC_URI="https://github.com/CadQuery/pywrap/archive/refs/tags/${MY_P}.tar.gz"
-
-# The official pywrap 7.4.0 tarball is broken, but pywrap 7.5.3 has yet to be
-# officially released. We instead package a commit known to work as expected.
-MY_COMMIT="66e7376d3a27444393fc99acbdbef40bbc7031ae"
-SRC_URI="https://github.com/CadQuery/pywrap/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-KEYWORDS="~amd64 ~x86"
-SLOT="0"
-
-# Dependencies are intentionally listed in "setup.py" order.
-RDEPEND="
- dev-python/click[${PYTHON_USEDEP}]
- dev-python/logzero[${PYTHON_USEDEP}]
- dev-python/path[${PYTHON_USEDEP}]
- dev-python/clang-python[${PYTHON_USEDEP}]
- dev-python/cymbal[${PYTHON_USEDEP}]
- dev-python/toml[${PYTHON_USEDEP}]
- dev-python/pandas[${PYTHON_USEDEP}]
- >=dev-python/joblib-1.0.0[${PYTHON_USEDEP}]
- dev-python/tqdm[${PYTHON_USEDEP}]
- dev-python/jinja[${PYTHON_USEDEP}]
- dev-python/toposort[${PYTHON_USEDEP}]
- dev-python/pyparsing[${PYTHON_USEDEP}]
- dev-python/pybind11[${PYTHON_USEDEP}]
- dev-python/schema[${PYTHON_USEDEP}]
- sci-libs/vtk
-"
-DEPEND="${RDEPEND}"
-
-S="${WORKDIR}/pywrap-${MY_COMMIT}"
-
-src_prepare() {
- #FIXME: Submit an upstream issue. This violates PEP 440 standards.
- # Sanitize the "bindgen" version to avoid Gentoo QA notices.
- sed -i -e 's~\(version=\)"0.1dev"~\1"'$(ver_rs 3 '')'"~' setup.py || die
-
- # Replace conda- with Gentoo-specific prefix dirnames.
- sed -i -e "s~\\bgetenv('CONDA_PREFIX')~'${EPREFIX}/usr'~" bindgen/*.py ||
- die
-
- # Reduce all hardcoded header includes to noops.
- sed -i -e 's~rv\.append(Path(prefix).*~True~' bindgen/utils.py || die
-
- distutils-r1_src_prepare
-}
diff --git a/dev-python/cadquery-pywrap/metadata.xml b/dev-python/cadquery-pywrap/metadata.xml
deleted file mode 100644
index aef989a0c..000000000
--- a/dev-python/cadquery-pywrap/metadata.xml
+++ /dev/null
@@ -1,12 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
- <maintainer type="project">
- <email>sci@gentoo.org</email>
- <name>Gentoo Science Project</name>
- </maintainer>
- <stabilize-allarches/>
- <upstream>
- <remote-id type="github">CadQuery/pywrap</remote-id>
- </upstream>
-</pkgmetadata>
diff --git a/dev-python/cadquery/Manifest b/dev-python/cadquery/Manifest
deleted file mode 100644
index 2b4ddbec1..000000000
--- a/dev-python/cadquery/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST cadquery-2.2_rc20220506.tar.gz 2872821 BLAKE2B a48b4279a6e24166842c3f7c43e0ff3552f22f8821fa203fce30b76110423c375019228b1a458b0020ebfd23a052545ae0d90e3246619a2e53dbe8f411449f3d SHA512 65bd62268f920d1fa170921033c4e4f451e1bdf7e4d1cef457bf34c4466a076de57f40d38ed7fb1d8f207b45447d6763a52880d9d49426372b06fefd536e7c17
diff --git a/dev-python/cadquery/cadquery-2.2_rc20220506.ebuild b/dev-python/cadquery/cadquery-2.2_rc20220506.ebuild
deleted file mode 100644
index 29edf6601..000000000
--- a/dev-python/cadquery/cadquery-2.2_rc20220506.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-DISTUTILS_SINGLE_IMPL=1
-PYTHON_COMPAT=( python3_10 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python parametric CAD scripting framework based on OCCT"
-HOMEPAGE="https://cadquery.readthedocs.io"
-
-# The official CadQuery 2.1 tarball requires the obsolete OCCT 7.4.0, but
-# CadQuery 2.2 has yet to be officially released. We instead package a commit
-# known to work as expected with OCCT 7.5.2.
-MY_COMMIT="803a05e78c233fdb537a8604c3f2b56a52179bbe"
-
-#FIXME: Uncomment on bumping to the next stable release.
-# SRC_URI="https://github.com/CadQuery/cadquery/archive/refs/tags/${PV}.tar.gz"
-SRC_URI="https://github.com/CadQuery/cadquery/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-# Hard masking since package depends on dev-python/cadquery-ocp, which depends on sci-libs/opencascade, which is no longer available from ::gentoo in the required slot.
-KEYWORDS=""
-#KEYWORDS="~amd64 ~x86"
-
-# Dependencies are intentionally listed in "conda/meta.yml" order. Due to its
-# Anaconda focus, "setup.py" currently fails to list dependencies.
-BDEPEND="
- test? (
- $(python_gen_cond_dep '
- dev-python/docutils[${PYTHON_USEDEP}]
- dev-python/path[${PYTHON_USEDEP}]
- ')
- )
-"
-RDEPEND="
- >=dev-python/cadquery-ocp-7.5.0[${PYTHON_SINGLE_USEDEP}]
- $(python_gen_cond_dep '
- >=dev-python/pyparsing-2.0.0[${PYTHON_USEDEP}]
- dev-python/ezdxf[${PYTHON_USEDEP}]
- dev-python/ipython[${PYTHON_USEDEP}]
- dev-python/typing-extensions[${PYTHON_USEDEP}]
- dev-python/nptyping[${PYTHON_USEDEP}]
- sci-libs/nlopt[python,${PYTHON_USEDEP}]
- dev-python/multimethod[${PYTHON_USEDEP}]
- dev-python/typish[${PYTHON_USEDEP}]
- ')
-"
-DEPEND="${RDEPEND}"
-
-S="${WORKDIR}/${PN}-${MY_COMMIT}"
-
-distutils_enable_tests pytest
-
-#FIXME: Uncomment after packaging "dev-python/sphinx-autodoc-typehints".
-# distutils_enable_sphinx docs dev-python/sphinx_rtd_theme dev-python/sphinx-autodoc-typehints
diff --git a/dev-python/cadquery/metadata.xml b/dev-python/cadquery/metadata.xml
deleted file mode 100644
index 86166e277..000000000
--- a/dev-python/cadquery/metadata.xml
+++ /dev/null
@@ -1,12 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
- <maintainer type="project">
- <email>sci@gentoo.org</email>
- <name>Gentoo Science Project</name>
- </maintainer>
- <stabilize-allarches/>
- <upstream>
- <remote-id type="github">CadQuery/cadquery</remote-id>
- </upstream>
-</pkgmetadata>
diff --git a/profiles/package.mask b/profiles/package.mask
index 9f3b8e7f5..d39812beb 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -29,10 +29,3 @@
## app-misc/some-package
#--- END OF EXAMPLES ---
-
-# Andrew Ammerlaan <andrewammerlaan@gentoo.org> (26 Jun 2023)
-# Depends on removed dev-python/toml.
-# Alternatives are tomli or tomlkit
-dev-python/cadquery
-dev-python/cadquery-ocp
-dev-python/cadquery-pywrap