app-crypt/swtpm: add USE=+openssl as default crypto provider

Bug: https://bugs.gentoo.org/909754
Signed-off-by: Matthias Maier <tamiko@gentoo.org>

2 files changed, 77 insertions, 0 deletions

diff --git a/app-crypt/swtpm/metadata.xml b/app-crypt/swtpm/metadata.xml
index 3187cf4dce7f..56af2735d414 100644
--- a/app-crypt/swtpm/metadata.xml
+++ b/app-crypt/swtpm/metadata.xml
@@ -15,6 +15,8 @@
 	</maintainer>
 	<use>
 		<flag name="fuse">Support <pkg>sys-fs/fuse</pkg> based /dev/tpm interface</flag>
+		<flag name="gnutls">Use <pkg>net-libs/gnutls</pkg> as crypto engine</flag>
+		<flag name="openssl">Use <pkg>dev-libs/openssl</pkg> as crypto engine</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">stefanberger/swtpm</remote-id>
diff --git a/app-crypt/swtpm/swtpm-0.8.0-r1.ebuild b/app-crypt/swtpm/swtpm-0.8.0-r1.ebuild
new file mode 100644
index 000000000000..dc312dd8bd52
--- /dev/null
+++ b/app-crypt/swtpm/swtpm-0.8.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="Libtpms-based TPM emulator"
+HOMEPAGE="https://github.com/stefanberger/swtpm"
+SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="fuse gnutls seccomp +openssl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="fuse? (
+		dev-libs/glib:2
+		sys-fs/fuse:0
+	)
+	gnutls? (
+		dev-libs/libtasn1:=
+		>=net-libs/gnutls-3.4.0:=[tools,pkcs11]
+	)
+	openssl? (
+		dev-libs/libtasn1:=
+		dev-libs/openssl
+	)
+	seccomp? ( sys-libs/libseccomp )
+	acct-group/tss
+	acct-user/tss
+	dev-libs/openssl:0=
+	dev-libs/json-glib
+	dev-libs/libtpms"
+
+DEPEND="${RDEPEND}
+	test? (
+		net-misc/socat
+		dev-tcltk/expect
+	)"
+
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.6.0-fix-localca-path.patch"
+	"${FILESDIR}/${PN}-0.5.0-build-sys-Remove-WError.patch"
+	"${FILESDIR}/${PN}-0.7.2-Conditionalize-test-dependencies.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-openssl \
+		--without-selinux \
+		$(use_with fuse cuse) \
+		$(use_with gnutls) \
+		$(use_with openssl) \
+		$(use_with seccomp) \
+		$(use_enable test)
+}
+
+src_install() {
+	default
+	fowners -R tss:root /var/lib/swtpm-localca
+	fperms 750 /var/lib/swtpm-localca
+	keepdir /var/lib/swtpm-localca
+	find "${D}" -name '*.la' -delete || die
+}