app-editors/pluma-plugins: remove support for all USE other than python

They control inert files installed to the plugins directory, and you
have to enable the plugins in the pluma settings.

Half these plugins require nothing other than python itself, and cannot
be disabled other than via --disable-python, which means offering to
refrain from installing them is a QA violation of PG-0301 (installation
of small files).

The remaining plugins have trivially satisfiable dependencies and still
violate the small files policy. The build system provides zero help
here, since the dependencies are automagically detected and there is no
option to disable them.

Having 5 different USE flags on top of the python one is pointless
complexity, so delete them.

...

Also while we are moving the USE-dependent plugin dependencies into the
python block? dbus-python was missing a USEDEP on the python impl, so
even enabling synctex would not actually help... add that in properly.

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 72 insertions, 0 deletions

diff --git a/app-editors/pluma-plugins/pluma-plugins-1.26.0-r3.ebuild b/app-editors/pluma-plugins/pluma-plugins-1.26.0-r3.ebuild
new file mode 100644
index 000000000000..cf3247965042
--- /dev/null
+++ b/app-editors/pluma-plugins/pluma-plugins-1.26.0-r3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MATE_LA_PUNT="yes"
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit mate python-single-r1
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A set of plugins for Pluma, the MATE text editor."
+LICENSE="FDL-1.1+ GPL-2+ LGPL-2+"
+SLOT="0"
+
+IUSE="+python"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=dev-libs/libpeas-1.14.1:0[gtk]
+	>=app-editors/pluma-1.25.3
+
+	>=dev-libs/glib-2.32:2
+	>=x11-libs/gtk+-3.9:3
+	>=x11-libs/gtksourceview-4.0.2:4
+
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			app-editors/pluma[${PYTHON_SINGLE_USEDEP}]
+			dev-libs/libpeas:0[python,${PYTHON_SINGLE_USEDEP}]
+			>=dev-python/dbus-python-0.82[${PYTHON_USEDEP}]
+			dev-python/pycairo[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+			>=dev-python/dbus-python-0.82[${PYTHON_USEDEP}]
+			>=x11-libs/vte-0.52:2.91[introspection]
+		')
+		>=x11-libs/gtk+-3.9:3[introspection]
+		>=x11-libs/gtksourceview-4.0.2:4[introspection]
+		x11-libs/pango[introspection]
+		x11-libs/gdk-pixbuf:2[introspection]
+
+	)"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable python)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	mate_src_install
+	use python && python_optimize "${ED}/usr/$(get_libdir)/gedit/plugins/"
+}