app-emacs/emacs-ipython-notebook: bump to 0.17.1_pre20230826

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/app-emacs/emacs-ipython-notebook/Manifest b/app-emacs/emacs-ipython-notebook/Manifest
index 41326ee84aa3..c864dcc0f93f 100644
--- a/app-emacs/emacs-ipython-notebook/Manifest
+++ b/app-emacs/emacs-ipython-notebook/Manifest
@@ -1 +1,2 @@
 DIST emacs-ipython-notebook-0.17.0_p20220419.tar.gz 313340 BLAKE2B 5ab9b82d8d17c3f64c375de7638aa4006e7dc47137260ab0a8222f7c507a54b32aa145d1630b3d0018c8303e0f116da81b61df27cd401875dfad5fd49ecdae13 SHA512 f6c2c293e7d2ddcba9dfac751523e0f8d55047ed01d4546ba1ece1f8833a1d54a1bcc066f34f06e111c34baee21a97c2ede2d90d188d7a05f407631acfd74037
+DIST emacs-ipython-notebook-0.17.1_pre20230826.tar.gz 312767 BLAKE2B 742df1a4fdf8409d711bd9903baa103cd28d110400f46c97e0fc0962e1ef3cf4f0fb696881bb54d83c7e1d342669dcd493e5e24067f6f439a8639dcef2140dae SHA512 1df8551c75fbd8e3c0543ec304cae9974024e36710fb6e7f418c4c8052bbfdefde357000e4df135ddbc58faf808d9bdf1ec731113e317500ad5fed48c1d1bd6f
diff --git a/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.1_pre20230826.ebuild b/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.1_pre20230826.ebuild
new file mode 100644
index 000000000000..83f23a778891
--- /dev/null
+++ b/app-emacs/emacs-ipython-notebook/emacs-ipython-notebook-0.17.1_pre20230826.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# NOTICE: Check package version in "lisp/ein-pkg.el".
+# NOTICE: File "lisp/ein-pkg.el" is needed by the "ein:dev-sys-info" function.
+
+EAPI=8
+
+[[ "${PV}" == *20230826 ]] && COMMIT=998ba22660be2035cd23bed1555e47748c4da8a2
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit elisp readme.gentoo-r1 python-single-r1
+
+DESCRIPTION="Jupyter notebook client in Emacs"
+HOMEPAGE="https://github.com/millejoh/emacs-ipython-notebook/"
+SRC_URI="https://github.com/millejoh/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${COMMIT}
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-emacs/anaphora
+	app-emacs/dash
+	app-emacs/deferred
+	app-emacs/polymode
+	app-emacs/request
+	app-emacs/websocket
+	app-emacs/with-editor
+	$(python_gen_cond_dep '
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/ert-runner
+		app-emacs/mocker
+	)
+"
+
+DOCS=( README.rst thumbnail.png )
+DOC_CONTENTS="There may be problems with connecting to Jupyter Notebooks
+	because of the tokens, in that case you can try running	\"jupyter
+	notebook\" with --NotebookApp.token=\"\" (and --NotebookApp.ip=127.0.0.1 to
+	limit connections only to local machine), but be warned that this can
+	compromise your system if used without caution! For reference check out
+	https://github.com/millejoh/emacs-ipython-notebook/issues/838"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+	#  * ACCESS DENIED:  open_wr: ~/.config/python/jupyter/migrated
+	unset JUPYTER_CONFIG_DIR
+
+	elisp_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	BYTECOMPFLAGS="-L lisp" elisp-compile lisp/*.el
+}
+
+src_test() {
+	ert-runner -L lisp -L test -l test/testein.el \
+		--reporter ert+duration test/test-ein*.el || die
+}
+
+src_install() {
+	elisp-install ${PN} lisp/*.el{,c}
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+
+	readme.gentoo_create_doc
+}