app-misc/fastfetch: add 2.0.5

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index b7844309693c..5195ed8852f7 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-1.12.2.tar.gz 538194 BLAKE2B bc6badbc7f690dacbe1408479286a0d42ec687526f776ff4d2ec7b0eb767032e5781cbbe37778f4dc03a5d386979a9ae2aab84c466be997b82d9a9a6c81ea78f SHA512 a82a7c7ae365335c20d659a82215cf320c4c6b07ff127c4dad322a0a01f7ec57e34d229f4953108daadcd0d243c84f8504a3b4367df5e255e5a06e685fd6739a
 DIST fastfetch-2.0.3.tar.gz 771351 BLAKE2B 7a17792dc9cce97de6d1363f5b5a224fbbf11e968ba7d2d2f9e226df319c01a2338d373e5ea3439c77e79b0b5dc490aab4f2fca0f4bba7276de750d9a6513807 SHA512 7a944b80feb46ab8151ffbc90482412eb6321aa3e19cf9531102f665e035ef1e1fe9d66655c61721991c0c50af2d51d48973299885b31cef44ee0631d42d4d49
 DIST fastfetch-2.0.4.tar.gz 771440 BLAKE2B 496a6ccf0b121c3a27f3919b82207e517bec0554bc2e16ba114650d1f5fa9f8141b6f2eee5385fe4a21df1f5c2d3da49db5263f294279a0f05d3aa951bd14469 SHA512 8912cd3b469b5bfcfe51b68229957c0ec09f32f6223e0230a9b9625d1a72ad3a55ff0b538e6ea5cf43acae31e20ea58e6499136051674585fbd2a3d7f428fef6
+DIST fastfetch-2.0.5.tar.gz 772840 BLAKE2B f8eb5a662455ac1599eea5b6486ea2208487b363464c23a94ca9f1c19e275ab81f3b033789527bb7137b8379f74b52a313e593c9a4dd590acafb5a2af77e383b SHA512 91c506407538f1e59c38ade63d7112be9d1040e5b322d578698e3e35e857d7f473a13805760548a49b0e0757a93c54339b6a9b09a3675e0d7e86f1527b9b2cde
diff --git a/app-misc/fastfetch/fastfetch-2.0.5.ebuild b/app-misc/fastfetch/fastfetch-2.0.5.ebuild
new file mode 100644
index 000000000000..1123fe0aba3a
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.0.5.ebuild
@@ -0,0 +1,105 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	dev-libs/yyjson
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}