app-misc/pdfpc: version bump to 4.3.2, update to EAPI-7

* raise minimum vala version to 0.34 per upstream
* raise maximum vala version to 0.42 per testing
* move vala to BDEPEND
* slot-depend on app-text/poppler
* make USE="gstreamer" default since that's upstream's default
* fix license GPL-2 -> GPL-2+

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Tiziano Müller <dev-zero@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/app-misc/pdfpc/pdfpc-4.3.2.ebuild b/app-misc/pdfpc/pdfpc-4.3.2.ebuild
new file mode 100644
index 000000000000..acb64556e3fd
--- /dev/null
+++ b/app-misc/pdfpc/pdfpc-4.3.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VALA_MIN_API_VERSION="0.34"
+VALA_MAX_API_VERSION="0.42" # fix sed line if you increase this
+
+inherit vala cmake-utils
+
+DESCRIPTION="Presenter console with multi-monitor support for PDF files"
+HOMEPAGE="http://pdfpc.github.io"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gstreamer"
+
+RDEPEND="app-text/poppler:=[cairo]
+	dev-libs/glib:2
+	dev-libs/libgee:0.8
+	gnome-base/librsvg
+	gstreamer? ( media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+	sys-apps/dbus
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}"
+BDEPEND="$(vala_depend)"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	sed -i -e "s/valac/valac valac-0.42 valac-0.40 valac-0.36 valac-0.34/" cmake/vala/FindVala.cmake || die
+	vala_src_prepare
+}
+
+src_configure(){
+	local mycmakeargs=(
+		-DSYSCONFDIR="${EPREFIX}/etc"
+		-DMOVIES=$(usex gstreamer on off)
+	)
+	cmake-utils_src_configure
+}