dev-lang/swi-prolog: bump development version

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 107 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index e3dbe78584be..7c8abb53fd44 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -1,4 +1,6 @@
+DIST swi-prolog-8.3.12-gentoo-patchset-0.tar.gz 716 BLAKE2B fc7cdc4d79d1edbfede6bb2f2b08282a3a445277d9869e91f6f91446469b73b125fe0df101124ec811c64b713561feeedbf3c1edd6a48ac01b0dc4c3184e44bc SHA512 279b8571e13eaee2a7b5ad92c6c1081be1160df0e275ce76495d721d8ced53dca6329f7cd950e0a87f7e30f6ab419ad14ab5ec725c4b90d0ff93d8c9d2366ce3
 DIST swipl-8.2.1.tar.gz 10969688 BLAKE2B 754678d9683999b681e62321423df01c4d28ac0aefb5b836134790112a76a2710cc3b433d381f4b11756727037cada026a2778445fe533f51a5543332ca86e82 SHA512 b49fa0832b4bad3b48256c97538172a06e7a4c50b55823dad345360f98055f0702e7a10fb2bfdb636e3fd99557bcb243cfccbaccb7546cb2afd13335f1c09db8
 DIST swipl-8.2.2.tar.gz 11002077 BLAKE2B 581c3ea83d2440cbe2454ba12ea2752bec9fda926f3afef6e36de1bbf70b43b34931ad768335bb15809a3d76959c7eec7dd3ad54a0a4085ad8ba34075dd3f4d9 SHA512 fb77cfd58932dc35c3d808899c1f493ffb22a58f56fe364ce0c0b48b8cabdd204d4f920346c39f696fadd9ee8335e163a8eb8d0a770c2835d803f030c1f3f878
 DIST swipl-8.3.10.tar.gz 11095901 BLAKE2B ff695f3a9ed77b8062c8e19fe0f099b3fe1a2ed84beacd965f133d2fa4c2b873ce95d0af6a71a9c5f8c8033b6026e72585ad36dbd7537cb90c5bd98bf852cff7 SHA512 f34e53df42ba3cfdce6be96a2c5dba9ecd0a938f1df9824522c852d8d1b7e42e1de96cebd7c988d9e9091a12cfc791f3916e198e8bb08e8798fc8b196c48058d
 DIST swipl-8.3.11.tar.gz 11098611 BLAKE2B 5ec01773be2466ac8e35f9cba5a5ce4b5c96beafed6e294ecff649a24dbfa332d1280d3022a379a68d8bee2080efb2616737a5e7f4113cc5301e7f4b8fc9a089 SHA512 f0d6bd40127d077a04028c9800c798f6745d80f9852b38d770bd9b1a4778652a90d13c04be1fb4f650c250bb95f9a7e576bfc6c298f8eac608cc96edadb77963
+DIST swipl-8.3.12.tar.gz 11099881 BLAKE2B adbf262457e96371f29e2e002fc5e0e927a417259e57e722334481ce16284a19e850cb3d4bac7696140645a80b1257d1210643900d79deeb9b3abbe5cf39da6e SHA512 30e0d0db70bdca2457a629046db571d17a4b25c705f56c8077f5798ffac9a62020f472165ede7aec0be68a0bcaf71d787108452505fe3fa30ff894445a37882a
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.12.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.12.ebuild
new file mode 100644
index 000000000000..94f5ee838f47
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.12.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz
+	https://dev.gentoo.org/~keri/distfiles/swi-prolog/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}