dev-libs/dqlite: add 1.16.2

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 52 insertions, 0 deletions

diff --git a/dev-libs/dqlite/Manifest b/dev-libs/dqlite/Manifest
index 86f3b2c832d5..ad75e5362cd2 100644
--- a/dev-libs/dqlite/Manifest
+++ b/dev-libs/dqlite/Manifest
@@ -1 +1,2 @@
 DIST dqlite-1.16.0.tar.gz 216776 BLAKE2B 653eac56c237e466f8b57d43a62ad25b7b3bd72a2088345f66db53b6bce5cdd528d16f3440572e5af8536fafde3f3cbb7700898479f1cd62b273e2192160ad15 SHA512 f9bc7ea3021d72bd81fe487d1c11b86a566002e2b1ddf6000b0fd54e407746ac35af079afc508d9d752de774dfee33c5c6e54c40c7884ac67a3bc7dca14ea362
+DIST dqlite-1.16.2.tar.gz 218814 BLAKE2B 00f1553f986b7b7089a86336e61b6fb560dc5bb8c6d0bd52f8268654674499d62283bd6c25d52c716f3baeac5bd1742d90b598705d8adf93b21e1788f014c6fd SHA512 45cb9b42866bd4955d9ff4513f5f14006bdf9a7217b1f699c46388e49ff7d98c08c0220a7fb9b00cf91d9ba9e1f3e4d660d0bd40d8423d185e81c932624e97b9
diff --git a/dev-libs/dqlite/dqlite-1.16.2.ebuild b/dev-libs/dqlite/dqlite-1.16.2.ebuild
new file mode 100644
index 000000000000..f3a5256c78dd
--- /dev/null
+++ b/dev-libs/dqlite/dqlite-1.16.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Embeddable, replicated and fault tolerant SQL engine"
+HOMEPAGE="https://dqlite.io/ https://github.com/canonical/dqlite"
+SRC_URI="https://github.com/canonical/dqlite/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3-with-linking-exception"
+SLOT="0/1.15.1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Upstream change from canonical to cowsql resetted raft's SONAME, 3 -> 0. bgo#915960
+# Keeping dev-libs/raft:= for a while due to that.
+RDEPEND="dev-db/sqlite:3
+	dev-libs/libuv:=
+	>=dev-libs/raft-0.18.1:="
+DEPEND="${RDEPEND}
+	test? ( dev-libs/raft[lz4,test] )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/dqlite-1.12.0-disable-werror.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-backtrace
+		--disable-debug
+		--disable-sanitize
+		--disable-static
+
+		# Will build a bundled libsqlite3.so.
+		--enable-build-sqlite=no
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}