dev-libs/libfilezilla: 0.34.0 bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-libs/libfilezilla/libfilezilla-0.34.0.ebuild b/dev-libs/libfilezilla/libfilezilla-0.34.0.ebuild
new file mode 100644
index 000000000000..91f14170584c
--- /dev/null
+++ b/dev-libs/libfilezilla/libfilezilla-0.34.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit flag-o-matic
+
+DESCRIPTION="C++ library offering some basic functionality for platform-independent programs"
+HOMEPAGE="https://lib.filezilla-project.org/"
+SRC_URI="https://download.filezilla-project.org/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0/21" # libfilezilla.so version
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/nettle:0=
+	>=net-libs/gnutls-3.5.7:=
+	virtual/libcrypt:=
+"
+DEPEND="${RDEPEND}
+	test? ( dev-util/cppunit )"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if ! test-flag-CXX -std=c++14; then
+			eerror "${P} requires C++14-capable C++ compiler. Your current compiler"
+			eerror "does not seem to support -std=c++14 option. Please upgrade your compiler"
+			eerror "to gcc-4.9 or an equivalent version supporting C++14."
+			die "Currently active compiler does not support -std=c++14"
+		fi
+	fi
+}
+
+src_configure() {
+	if use ppc || use arm || use hppa; then
+		# bug 727652
+		append-libs -latomic
+	fi
+
+	econf --disable-static
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+}