dev-python/async_timeout: Use PEP517 build

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild b/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild
new file mode 100644
index 000000000000..226c647c7974
--- /dev/null
+++ b/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${PN/_/-}-${PV}
+DESCRIPTION="Timeout context manager for asyncio programs"
+HOMEPAGE="
+	https://github.com/aio-libs/async-timeout/
+	https://pypi.org/project/async-timeout/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pointless dep on pytest-cov
+	sed -i -e '/addopts/d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest -p no:aiohttp
+}