dev-python/bokeh: version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/bokeh/Manifest b/dev-python/bokeh/Manifest
index 76d6e2271aff..72bb1e0c67ff 100644
--- a/dev-python/bokeh/Manifest
+++ b/dev-python/bokeh/Manifest
@@ -1,2 +1,3 @@
 DIST bokeh-0.11.1.tar.gz 3383140 SHA256 34a73d8f68e7d6faaecc9f785cac8e9f76b88a7e7aacf66307076b03b4d3c472 SHA512 18cfee85698f1ba548c34fb223dc57e36584951064e65fac83cb8388b129914a8f67970a133ef2d1a67c06e50cbfb565a27d33dc9c90f5027a1739d400894706 WHIRLPOOL 5f8aa63f90e95945b7c1e1770d869ee7b8aee34d07f6f254586de5d30561b1688f5390f688f9792627809229fb93fcf607a012dc5e070a5c8f7c95b84dd8db4d
 DIST bokeh-0.12.4.tar.gz 5584657 SHA256 4fa2360f4492785d47c898be72374f0123bf8e8a939824ed1d1610f1ce30b2a0 SHA512 bab043278cf580a7d6df9749d7ceca763fc77849de37a8ea7e5a674714a5e49c240ea41ec964fd00cb6d71901fd349f10ee732df5dc5a853e0a2ea8a9c97b1ef WHIRLPOOL 112e87e14c72a690ce5a979d53015b0e5753992e95906d8c93ba69a6b66d25315a1e57d3a6b7801d1706720879e495280f42d80ac7876be4a17ca0784ee0dbb0
+DIST bokeh-0.12.6.tar.gz 13720124 SHA256 a2ddcc694c387440a2b361e741d2fa9a18ad0508a879a71f524a2f0ff7803181 SHA512 7a293169521b690bb2cdcefe3667f869e75f2b718d6122af63201e2fb2e530eba931b3fa2ee3474a8ead758039cbb7d756acc0349e2f0820d72a4f754b9301b2 WHIRLPOOL 0a2c46e1cef3e44c81d965f70a82129286308a19175c4ae4bc2c5861a1b2d699782229569c2f32137169d6e295b2c2b17d15f06630d56d4772b3de1bb018d7d2
diff --git a/dev-python/bokeh/bokeh-0.12.6.ebuild b/dev-python/bokeh/bokeh-0.12.6.ebuild
new file mode 100644
index 000000000000..9d2c39b2d3d5
--- /dev/null
+++ b/dev-python/bokeh/bokeh-0.12.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Statistical and interactive HTML plots for Python"
+HOMEPAGE="http://bokeh.pydata.org/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.3[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=net-libs/nodejs-4.1
+	>=www-servers/tornado-4.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/boto[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/flexx[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile() {
+	esetup.py build --build-js
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	py.test -m 'not (js or examples or integration)' -vv || die
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}