dev-python/jupyter_console: Version bump to 5.0.0

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1959

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/jupyter_console/jupyter_console-5.0.0.ebuild b/dev-python/jupyter_console/jupyter_console-5.0.0.ebuild
new file mode 100644
index 000000000000..47bdca6a98cc
--- /dev/null
+++ b/dev-python/jupyter_console/jupyter_console-5.0.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="A terminal-based console frontend for Jupyter kernels"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-1.0.0[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests --with-coverage --cover-package=jupyter_console jupyter_console || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}