dev-python/moto: Bump to 5.0.15

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 123 insertions, 0 deletions

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 42fe35fc016a..bd511e29ad67 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -2,3 +2,4 @@ DIST moto-4.2.14.tar.gz 4933741 BLAKE2B 4c50a808dc8f27cfbcd0ba234d268084ee9a32f3
 DIST moto-5.0.12.tar.gz 5345173 BLAKE2B 89bc77ab9409b6ccacbab350c77d3074c0adadf796b262d64e3a6ea11377b6e21f72a5223de6d34ab4d810fe6d80f3ed0beccc46a735d72bca344445b55300c0 SHA512 662843971f8c0c9169679097428d690a51ce70157738aadd6dca05cdf13643702a2ae0760865a4d6872b0e8585b06bc21369030b4b4ebbd285a1df8a765cd411
 DIST moto-5.0.13.tar.gz 5389183 BLAKE2B 9428f5857ccf9082a985c90281267cde65f15fc970cbc43e00d6a38663c6786d1d8cd5aede4f01a0bb69c65bfa156e7b12336f19e0e2ff9da44291a367583eb0 SHA512 5fd3fcf4404e61056170eb187c4f9acb42b4178ad56ee44a74fdf423c061aa7455fb1ce4f34e0517e7eadeb2ffb32ea9485c100772fd89d4c12bb8956b2797c0
 DIST moto-5.0.14.tar.gz 5436824 BLAKE2B 9bcab90605a73c9b03c09285a00055c552437545b6d524377cec816ac569e4a1e399d84ccdd54ac0c1ac00ae253f8849bb5c3892e8d95021d31fa5c05705b3ba SHA512 063fe3b518263f0dfb9d0dc569d537bcbaba4a439e4945806c641cd7b0bc32e7431972ae800d4d581b1ae200122f5d22870faf8ce025377c174360cad2896aa5
+DIST moto-5.0.15.tar.gz 5465282 BLAKE2B c043b0cf5ce42d0633f25ab874e787315367836d54c59ceedc3e85a161b01974671eb6dd42916e45ccaaaab9a48bfa217c0b8f22fbd817da3d2a9b4ee4522a03 SHA512 95c20146d6d5dcb6b49c3bb90e23bc6b656f6773267263bfd6a4f069a572311ef47cde3e1797dce78cfa38a28894b5deaf5e1bbe4bfcde3b49cfeea90cc63b25
diff --git a/dev-python/moto/moto-5.0.15.ebuild b/dev-python/moto/moto-5.0.15.ebuild
new file mode 100644
index 000000000000..638807e5d974
--- /dev/null
+++ b/dev-python/moto/moto-5.0.15.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_core/test_request_passthrough.py
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_aws_and_http_requests
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_http_requests
+		# broken code? (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		# require py_partiql_parser
+		tests/test_s3/test_s3_select.py
+		tests/test_dynamodb/test_dynamodb_statements.py
+		# require joserfc
+		tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+		tests/test_apigateway/test_apigateway.py::test_create_authorizer
+		tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+		tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+		tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+	)
+
+	# test for 32-bit time_t
+	"$(tc-getCC)" ${CFLAGS} ${CPPFLAGS} -c -x c - -o /dev/null <<-EOF &>/dev/null
+		#include <sys/types.h>
+		int test[sizeof(time_t) >= 8 ? 1 : -1];
+	EOF
+
+	if [[ ${?} -eq 0 ]]; then
+		einfo "time_t is at least 64-bit long"
+	else
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+			tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+			tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+		)
+		EPYTEST_IGNORE+=(
+			tests/test_route53domains/test_route53domains_domain.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+
+	rm -rf moto || die
+	epytest -m 'not network and not requires_docker' \
+		-p rerunfailures --reruns=5
+}