dev-python/pikepdf: Bump to 7.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 697b039b26c9..980876de8653 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -3,3 +3,4 @@ DIST pikepdf-6.2.7.gh.tar.gz 2906211 BLAKE2B bfc3d8e707b952e214fda3e31ecb0cb4426
 DIST pikepdf-6.2.8.gh.tar.gz 2906054 BLAKE2B 7b639741112857dbf784da7245f905e76664b200f4f832b6a2e8bbf7ab3e48e7f3a5dba1ae00bba72a5797e7e7bce0f1cea6777114ccf9a9b39d352a754edaeb SHA512 d27d8dcd80aa6a553ea6fb3c404bbe7752b2d1a7fb7a8e0315707f24243ff3fcdf58f273dc283e117a0124bfa724f7384004340f20d9f322cf08a5e0366b0225
 DIST pikepdf-6.2.9.gh.tar.gz 2906102 BLAKE2B bd876f506714b237a6010b72c4557bc600e2ee4d6621131c21902ae9f41eb39a9a54a6c08d08dfa84fb3eeec8f2ae7e256d1f1fde533dbc2660a2b415077c8a7 SHA512 2b16e51c999fe1d1f593a9079ae0f13fdaa1955b5d55023169e3a805cbdda07b7ca4108ecea66463a1a253712b851b6dc824aed2c80e5f0caa3ba398d413bd64
 DIST pikepdf-7.0.0.gh.tar.gz 2899924 BLAKE2B 0aeb5b9a26b8f5363ed62ac59e4ffd6dc11aba44c2d3248f8e47c31811cfb810ec7e11150e1bf64ea28242bb7749e3fa2f2fc2bded3af64123e39aa1e4595b8d SHA512 5a11b0a3f35f7d7071ad0553be598f9d2e2d95ce325c080c69e9551e07ebde0102f02990d5ef32be860b468fefc1c29d5f9ff581d1f75321314c52fb2de2f389
+DIST pikepdf-7.1.0.gh.tar.gz 2900167 BLAKE2B 1293e580257a0f077146e1dff37ce825ef504a62aaadbfc466ce77a491bdfc101e01c7f314dbc039f69df08924ad1dab8de74ffedd0675cfc8139895289f6405 SHA512 e8fee8a69c0d6a5d148b3d001bd72be341ae7294401777f06b698d261329850832fdc3ea2b6ab9d8abb9fb99b041fe7a1a5750a22846528c76a03019b3ac4ca5
diff --git a/dev-python/pikepdf/pikepdf-7.1.0.ebuild b/dev-python/pikepdf/pikepdf-7.1.0.ebuild
new file mode 100644
index 000000000000..9cf479f7a649
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-7.1.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	>=app-text/qpdf-11.1.1:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-9.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.{8..10})
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to system load
+	tests/test_image_access.py::test_random_image
+)
+
+src_prepare() {
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}