dev-python/pikepdf: Bump to 9.4.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index e3f1e2f8da2a..523479a60da9 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -4,3 +4,4 @@ DIST pikepdf-9.2.1.tar.gz 2905740 BLAKE2B cee801fcb231f2537ce75555b10d68de9acc62
 DIST pikepdf-9.3.0.tar.gz 2905550 BLAKE2B 62b3a1d655fb5b3e4d315a3feaeb14a043048c5985f5cf99812c07e1d248ae52cb1734dbd091103f36a3fd5a981c89b57208fb50f5c1081e08e3c20ec728ff9c SHA512 3325ab06c285f8f51c66c3815b15f96b0730e38f8023ce5c1e46818c581c38ab3bd89875e5de6ce1064a5929a8c386740d76e662c82d00d9c46961c56da4f0c0
 DIST pikepdf-9.4.0.tar.gz 2905478 BLAKE2B fea41290e14c9c3254993f5885270cee8b896f830b6c4a9297843f2754b189ca9d095d33564a95686ff381dc1151d078c587a9fef681fc29f0ede1ec5b61e1e4 SHA512 53be3ca19c3daff564aef4e07b025741d1d8ab6196bf14299059263d432ab5906d73e35b88d940b8429f44f5e595f30d70276f388687b9200d4b561fe1183b29
 DIST pikepdf-9.4.1.tar.gz 2905720 BLAKE2B 5292f4a0af9496ac6ea9db6c3a1d44d1d84d0724c5dea08995bb097bed1eeb26476593a3e9d19b594aed24031f24523271830f21fc9ce7b95ad949da35e236e5 SHA512 d9a4b5e38f62b19c4f989899b851e7155df0be2ea02ffbd06e4fbabab66d5cb76d45a89ec3bca3e6aac3c85ab9d16699c38a4262b52f1b23edd8e3b4b0e0343b
+DIST pikepdf-9.4.2.tar.gz 2914992 BLAKE2B daed44bd1106dbeadef449160e2ba5b389a1eeb7b23a32124a59b7861c1584d49feca01d6f54a18dc53eaace7823b23f62c1240c58445eb382ee25133b2d463b SHA512 2dc84672941a283da5486b2664252b6cd0612d7d2f9e8d10e3ae41f494be89821431568872b6b60045ffb2f1f687cea055093229ee443997997a8fae56e43e0b
diff --git a/dev-python/pikepdf/pikepdf-9.4.2.ebuild b/dev-python/pikepdf/pikepdf-9.4.2.ebuild
new file mode 100644
index 000000000000..041e2461025b
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-9.4.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="big-endian"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.12.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		!big-endian? (
+			>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		)
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.10)
+		media-libs/tiff[zlib]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e '/-n auto/d' -i pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile to system load
+		tests/test_image_access.py::test_random_image
+		tests/test_image_access.py::test_image_save_compare
+		tests/test_image_access.py::test_palette_nonrgb
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p timeout
+}