dev-python/pytest: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 114 deletions

diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 0da5b4c9a2cc..833d65d486e3 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,5 +1,4 @@
 DIST pytest-7.4.4.tar.gz 1357116 BLAKE2B 0bf281b3d4b7b2eb7805423a75c8c2befa820cc230318511e5a2d5ea35321a78a2603d5dbc033414ed73171525371efa9d9f54083d5638fc752c1c218e6d53aa SHA512 28a259dac6739683c131993409d508e10fbfee461291b8fc7697dd83f30725a3c60e681ba00b5669a215af6a5e683f07a329485d780acc9ad0372a6552f783a1
 DIST pytest-8.0.2.tar.gz 1396924 BLAKE2B ad95d246f5592cfe54faea6c96e38cb60d3e2713070d1ff7cab6c42aea312883c5d97c99a930dbcbd8493e966c4b8351320f6494b4ab904afbf21d7e1dd004a7 SHA512 c495943baad05e09b467d23c7afadb3edff7ae93ee96290d6db9e64739236888148b63dff7e8e25b331b11bd48c55fb0ca8901cf823d69b1a922e94915bab2f1
-DIST pytest-8.1.1.tar.gz 1409703 BLAKE2B 8e382c87af1bbbc235f9b27f8bb892d08393e0a9821f32373ee2546112c24dc6f90e1990f10ef799a94a1426a83a2bc3de0be9e7efde90cbf4eac5a0c9ee375c SHA512 f1a9f69cd4eca3ab36c36bc666bf70b099125ed6e17b89d13554c3f13b100d05abfd0b35516660d00ca4fb9eca81164ab02bc8f7a9a8d90fd4302bf399cd88c0
 DIST pytest-8.1.2.tar.gz 1410060 BLAKE2B 1379047c5ba434e98a383756c53a9cf31dc3bd3abcc49820f872b9110ec70906ca14080ce17ed2770b71195fbd79627a0eb16ee00429e165368144b20153a02b SHA512 a6ffae29da98ee4c357ebb03f00c4bc1a33f093ef867ad118841695548468c7f229eaa2c029a2ce3b158bbb0a65be5014e91555a223d04c1c72e614cb1d00546
 DIST pytest-8.2.0.tar.gz 1422883 BLAKE2B 91f39aa14bfc56f7f98789ef9eeed80d1aa81c864f56181bf1e819b73543043eda307fec53151bf5dbcf8e63abd8dd8ad1290dd245c387cb68583d2160981cf2 SHA512 1a74a2269010804101fc4b8efc370c5d8d484eb145eb4e181feeb1a17046457b97071d2de925c3e8bbd4c6090cd00ca532d69286cb9e10ea023e59a99cd51088
diff --git a/dev-python/pytest/pytest-8.1.1.ebuild b/dev-python/pytest/pytest-8.1.1.ebuild
deleted file mode 100644
index bc3240afb1d2..000000000000
--- a/dev-python/pytest/pytest-8.1.1.ebuild
+++ /dev/null
@@ -1,113 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_TESTED=( python3_{10..12} pypy3 )
-PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Simple powerful testing with Python"
-HOMEPAGE="
-	https://pytest.org/
-	https://github.com/pytest-dev/pytest/
-	https://pypi.org/project/pytest/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/iniconfig[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	<dev-python/pluggy-2[${PYTHON_USEDEP}]
-	>=dev-python/pluggy-1.4[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
-		>=dev-python/tomli-1[${PYTHON_USEDEP}]
-	' 3.10)
-	!!<=dev-python/flaky-3.7.0-r5
-"
-BDEPEND="
-	>=dev-python/setuptools-scm-6.2.3[${PYTHON_USEDEP}]
-	test? (
-		${RDEPEND}
-		$(python_gen_cond_dep '
-			dev-python/argcomplete[${PYTHON_USEDEP}]
-			>=dev-python/attrs-19.2[${PYTHON_USEDEP}]
-			>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
-			dev-python/mock[${PYTHON_USEDEP}]
-			>=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-			dev-python/requests[${PYTHON_USEDEP}]
-			dev-python/xmlschema[${PYTHON_USEDEP}]
-		' "${PYTHON_TESTED[@]}")
-	)
-"
-
-src_test() {
-	# workaround new readline defaults
-	echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
-	local -x INPUTRC="${T}"/inputrc
-	distutils-r1_src_test
-}
-
-python_test() {
-	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
-		einfo "Skipping tests on ${EPYTHON}"
-		return
-	fi
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	local -x COLUMNS=80
-
-	local EPYTEST_DESELECT=(
-		# broken by epytest args
-		testing/test_warnings.py::test_works_with_filterwarnings
-
-		# tend to be broken by random pytest plugins
-		# (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
-		testing/test_helpconfig.py::test_version_less_verbose
-		testing/test_helpconfig.py::test_version_verbose
-		testing/test_junitxml.py::test_random_report_log_xdist
-		testing/test_junitxml.py::test_runs_twice_xdist
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
-		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
-		testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
-		testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
-		testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
-
-		# unstable with xdist
-		testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
-
-		# TODO (XPASS)
-		testing/test_debugging.py::TestDebuggingBreakpoints::test_pdb_not_altered
-		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_simple
-		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_twice
-		testing/test_debugging.py::TestPDB::test_pdb_with_injected_do_debug
-		testing/test_debugging.py::test_pdb_suspends_fixture_capturing
-
-		# setuptools warnings
-		testing/acceptance_test.py::TestInvocationVariants::test_cmdline_python_namespace_package
-
-		# times out
-		testing/test_debugging.py::TestPDB::test_pdb_interaction_exception
-		testing/test_debugging.py::TestPDB::test_pdb_with_caplog_on_pdb_invocation
-	)
-
-	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
-		# regressions on pypy3.9
-		# https://github.com/pytest-dev/pytest/issues/9787
-		testing/test_skipping.py::test_errors_in_xfail_skip_expressions
-		testing/test_unraisableexception.py
-	)
-
-	local EPYTEST_XDIST=1
-	epytest
-}