dev-python/rq: Bump to 2.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index d5576c94eb41..0f644cef16f3 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-1.16.2.tar.gz 629881 BLAKE2B 69ac4ba43ea79ddf998bc9f7cf0fc5fa42acb0315dff663b1c924498ccfabdd37ac6d9613e128b838b9e1f45988632a337fb2fa50f5adcd1b69aa520b5ad33e2 SHA512 1c3162b1acffc9d11292fcbff7177267272a02e752b5839a4004b875bb5bb25af7e61f31041df438ef4e0e47152296c3a2711856c6a36d787848dcb766387d1a
+DIST rq-2.0.0.tar.gz 639193 BLAKE2B ec44a45618f4ba0cafd30d13d15db8efc26c35f41100019e94d28ac21ca0c6157df34c55fd9bc2c2afdd4752e815a45150c95840339744c005c297153795e598 SHA512 46878626ad939fdc3f31bfd04fab9d11f266a390fe75ea22fde62e1622607e715673a8f3d2e3aba78e489b861d16068836aea4eca5a88cd295d6b6ca61707a41
diff --git a/dev-python/rq/rq-2.0.0.ebuild b/dev-python/rq/rq-2.0.0.ebuild
new file mode 100644
index 000000000000..5cde9ca9c756
--- /dev/null
+++ b/dev-python/rq/rq-2.0.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unnecessary typechecking deps
+	sed -i -e '/types-/d' pyproject.toml || die
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires <sentry-sdk-2
+		tests/test_sentry.py::TestSentry::test_failure_capture
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}