dev-python/trio: Bump to 0.28.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 8b384899b094..9a402d9a1b56 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
 DIST trio-0.27.0.gh.tar.gz 617781 BLAKE2B 343e7e351c34cfa6176d9ae46ad2c4311793f47b8032713efbdc5ed1d152552260002a59b8e02e256a8241a32a9d21505f4354340bcca88a62ca16e8dc5c8a01 SHA512 10fb7b14a7dcccc7a8f04793a1c6992449bd9934726f5a2648fde2533a33cb38468ecd0de8f098544174d51046400bae32b435ed432085cf4d631c9feef88058
+DIST trio-0.28.0.gh.tar.gz 590844 BLAKE2B 4e9f89e0fd68db37bb07ee045809af8795216809885f79f6f247c7711be87995546f2db5a957f7ee5927edc60a442ed6d60a41cec7a559dd4acbc34d20435ba0 SHA512 2699cb55e237247737704852c34be6726746e35426c9a2ed3ca1a5e612a64fec0bd59e259bec4e88e1eb85c8d5a05e3f238346d8227ca0f9fcab271efe45bdd0
diff --git a/dev-python/trio/trio-0.28.0.ebuild b/dev-python/trio/trio-0.28.0.ebuild
new file mode 100644
index 000000000000..01b349cf4ec8
--- /dev/null
+++ b/dev-python/trio/trio-0.28.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.2.1[${PYTHON_USEDEP}]
+	' 3.10)
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# 	dev-python/immutables \
+# 	dev-python/sphinxcontrib-trio \
+# 	dev-python/sphinx-rtd-theme \
+# 	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+		# requires ruff
+		_tests/tools/test_gen_exports.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	rm -rf trio || die
+	epytest -p trio._tests.pytest_plugin \
+		-m "not redistributors_should_skip" \
+		--pyargs trio \
+		--skip-optional-imports
+}