dev-qt/qtconnectivity: add 6.6.0_rc

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-qt/qtconnectivity/Manifest b/dev-qt/qtconnectivity/Manifest
index 9f7b094b7b48..e32c7c37bbbe 100644
--- a/dev-qt/qtconnectivity/Manifest
+++ b/dev-qt/qtconnectivity/Manifest
@@ -1 +1,2 @@
 DIST qtconnectivity-everywhere-src-6.5.2.tar.xz 985972 BLAKE2B e7f3d8ad3580336d7eaff50e8ac2af3b291462544ebc5ca3d049d045a8388668d5e54a075375aaa9c99b3232ec07063dc4b7288bdc9fee83843fe57909e5e35b SHA512 76d9569ecfbbb4355587779a9aa0abf20f7d08484a2634e6c3b49a71b057451c54fd5fd344b4c376206384e5f1e9264a6bbbcd85ee44f15637c116f411d4aa30
+DIST qtconnectivity-everywhere-src-6.6.0-rc.tar.xz 989216 BLAKE2B ab69418fff788e3b78347c56c980850515ca36122e3c38d96f8990e4c813bd5553fb158a8cefef147baf307d72b5911e0f6acf0a21655568bbcba76b45d1d799 SHA512 0cb98794feb7273beb5438fd2efc8a01da018d12f81775e720195573fbf245d256b945eec04d25514fa4b47fd63f2b4af19b3ba1319221b2e9c588a8353a4fd0
diff --git a/dev-qt/qtconnectivity/qtconnectivity-6.6.0_rc.ebuild b/dev-qt/qtconnectivity/qtconnectivity-6.6.0_rc.ebuild
new file mode 100644
index 000000000000..47506d7b4b09
--- /dev/null
+++ b/dev-qt/qtconnectivity/qtconnectivity-6.6.0_rc.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Bluetooth and NFC support library for the Qt6 framework"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64"
+fi
+
+IUSE="+bluetooth nfc smartcard"
+REQUIRED_USE="|| ( bluetooth nfc )"
+
+RDEPEND="
+	~dev-qt/qtbase-${PV}:6[network]
+	bluetooth? (
+		~dev-qt/qtbase-${PV}:6[dbus]
+		net-wireless/bluez:=
+	)
+	nfc? (
+		smartcard? ( sys-apps/pcsc-lite )
+	)
+"
+DEPEND="${RDEPEND}"
+
+CMAKE_SKIP_TESTS=(
+	# most hardware tests are auto-skipped, but some still misbehave
+	# if bluez/hardware is available (generally tests here may not be
+	# very relevant without hardware, lists may need to be extended)
+	tst_qbluetoothlocaldevice
+	tst_qbluetoothserver
+	tst_qbluetoothservicediscoveryagent
+	tst_qbluetoothserviceinfo
+	tst_qlowenergycontroller
+)
+
+src_prepare() {
+	qt6-build_src_prepare
+
+	use bluetooth ||
+		sed -i '/add_subdirectory(bluetooth)/d' src/CMakeLists.txt || die
+	use nfc ||
+		sed -i '/add_subdirectory(nfc)/d' src/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(usev nfc $(qt_feature smartcard pcsclite))
+	)
+
+	qt6-build_src_configure
+}
+
+src_install() {
+	qt6-build_src_install
+
+	# broken (unnecessary) symlink due to add_app() being used over add_tool()
+	use !bluetooth || rm -- "${ED}"/usr/bin/sdpscanner6 || die
+
+	if use test; then
+		local delete=( # sigh
+			"${D}${QT6_BINDIR}"/bluetoothtestdevice
+			"${D}${QT6_BINDIR}"/bttestui
+			"${D}${QT6_BINDIR}"/qlecontroller-server
+		)
+		# using -f given not tracking which tests may be skipped or not
+		rm -f -- "${delete[@]}" || die
+	fi
+}