dev-qt/qtdeclarative: Drop USE xml

Missing follow-up to 359fc371b09aa331917b8f5af3b0019bed1252e0.

xmllistmodel was moved to qtdeclarative in upstream commit
0477a057fd02050fd330760bf046f5e0e91a9331.

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.12.1-r1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.12.1-r1.ebuild
new file mode 100644
index 000000000000..b3c3411fbb0a
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.12.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+IUSE="gles2 +jit localstorage +widgets"
+
+# qtgui[gles2=] is needed because of bug 504322
+COMMON_DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=]
+	~dev-qt/qtnetwork-${PV}
+	~dev-qt/qttest-${PV}
+	localstorage? ( ~dev-qt/qtsql-${PV} )
+	widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
+"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	!<dev-qt/qtquickcontrols-5.7:5
+"
+
+src_prepare() {
+	use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+	qt_use_disable_mod localstorage sql \
+		src/imports/imports.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/qmltest/qmltest.pro \
+		tests/auto/auto.pro \
+		tools/tools.pro \
+		tools/qmlscene/qmlscene.pro \
+		tools/qml/qml.pro
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		-qml-debug
+	)
+	qt5-build_src_configure
+}