proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-util/android-ndk/android-ndk-9.ebuild b/dev-util/android-ndk/android-ndk-9.ebuild
new file mode 100644
index 000000000000..18280c801516
--- /dev/null
+++ b/dev-util/android-ndk/android-ndk-9.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+MY_P="${PN}-r${PV}"
+
+DESCRIPTION="Open Handset Alliance's Android NDK (Native Dev Kit)"
+HOMEPAGE="http://developer.android.com/sdk/ndk/"
+SRC_URI="x86? ( http://dl.google.com/android/ndk/${MY_P}-linux-x86.tar.bz2
+	legacy-toolchains? ( http://dl.google.com/android/ndk/${MY_P}-linux-x86-legacy-toolchains.tar.bz2 ) )
+	amd64? ( http://dl.google.com/android/ndk/${MY_P}-linux-x86_64.tar.bz2
+	legacy-toolchains? ( http://dl.google.com/android/ndk/${MY_P}-linux-x86_64-legacy-toolchains.tar.bz2 ) )"
+
+LICENSE="android"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="legacy-toolchains"
+RESTRICT="mirror strip installsources test"
+
+DEPEND=""
+RDEPEND=">=dev-util/android-sdk-update-manager-10
+	>=sys-devel/make-3.81"
+
+S="${WORKDIR}/${MY_P}"
+
+ANDROID_NDK_DIR="opt/${PN}"
+
+QA_PREBUILT="*"
+
+src_configure() {
+	:
+}
+
+src_compile() {
+	:
+}
+
+src_install() {
+	dodir "/${ANDROID_NDK_DIR}"
+	cp -pPR * "${ED}/${ANDROID_NDK_DIR}" || die
+
+	fowners -R root:android "/${ANDROID_NDK_DIR}"
+	fperms 0775 "/${ANDROID_NDK_DIR}/"{,build,docs,platforms,samples}
+	fperms 0775 "/${ANDROID_NDK_DIR}/"{sources,tests,toolchains}
+
+	dodir "/${ANDROID_NDK_DIR}/out"
+	fowners root:android "/${ANDROID_NDK_DIR}/out"
+	fperms 3775 "/${ANDROID_NDK_DIR}/out"
+
+	ANDROID_PREFIX="${EPREFIX}/${ANDROID_NDK_DIR}"
+	ANDROID_PATH="${EPREFIX}/${ANDROID_NDK_DIR}"
+
+	for i in toolchains/*/prebuilt/linux-*/bin
+	do
+		ANDROID_PATH="${ANDROID_PATH}:${ANDROID_PREFIX}/${i}"
+	done
+
+	printf '%s' \
+		"PATH=\"${ANDROID_PATH}\"" \
+		$'\n' \
+		> "${T}/80${PN}"  || die
+
+	doenvd "${T}/80${PN}"
+
+	echo "SEARCH_DIRS_MASK=\"${EPREFIX}/${ANDROID_NDK_DIR}\"" \
+		> "${T}/80${PN}" || die
+	insinto "/etc/revdep-rebuild"
+	doins "${T}/80${PN}"
+}