dev-util/devhelp: bump to 3.36.2

Package-Manager: Portage-2.3.103, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-util/devhelp/Manifest b/dev-util/devhelp/Manifest
index a4b76e460429..a613bf2d4519 100644
--- a/dev-util/devhelp/Manifest
+++ b/dev-util/devhelp/Manifest
@@ -1 +1,2 @@
 DIST devhelp-3.34.0.tar.xz 288352 BLAKE2B 26c8c05c161e5607492fc26f012280468ed247ad4c166013e9df5fc1c76d59f98034a157cb58be9554ec65f46520b7d0d2ba78de00134570e84ca5a5ba0dc504 SHA512 34ed48ed323827b01f7d32e186da856c788ddfe37d6836082a81e6c8e4cd7bfc2265309cc3b298a0aea542b85e9261987d47a5a4396d865ec7e4cc13a9d05814
+DIST devhelp-3.36.2.tar.xz 302996 BLAKE2B 61131c7bedfe6803c04315138b017145e7ad7cc2939022a4cfcd0c65f4f3144db705a4a918a4ecd6a6fcea2a5dce64a891d951ccfc21dec0421991455b81ad16 SHA512 8852546b8ff337c2448a88b931803029825e34a6cf906370c683ac004866a548c9de79c934fde36ec04584f0bdc59eee4184b9ed8a480303eb78b9c9d43eb55e
diff --git a/dev-util/devhelp/devhelp-3.36.2.ebuild b/dev-util/devhelp/devhelp-3.36.2.ebuild
new file mode 100644
index 000000000000..22133dbacde5
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.36.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-3+ CC-BY-SA-4.0"
+SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+IUSE="gedit gtk-doc +introspection"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/glib-2.60:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=net-libs/webkit-gtk-2.24:4[introspection?]
+	>=gui-libs/amtk-5.0:5
+	gnome-base/gsettings-desktop-schemas
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			app-editors/gedit[introspection,python,${PYTHON_SINGLE_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/3.30.1-optional-introspection.patch
+	"${FILESDIR}"/3.30.1-optional-gedit.patch
+)
+
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dflatpak_build=false
+		$(meson_use gedit gedit_plugin)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	use gedit && python_optimize "${ED}"/usr/$(get_libdir)/gedit/plugins
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}