gnome-base/gnome-desktop: Version bump to 40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 441861d68353..c6ed3adfe75d 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-desktop-3.38.4.tar.xz 745168 BLAKE2B 1d85b176acb6721fb21bc56eef552629a06b059117cc53a5dde9c2c74ae23f624701efed3849e8e7daf21c1fd7622b747b394b6c63ab974371daec14bfb8d9ce SHA512 546fd2bd25d7582ae6cc6aa2beab4221fd246d16640e7d3f0cf9b700732f67a95c4bcb3211b5cb131f151b25923d59aa1ffa114183b6fcb683ad88cb94790e1e
+DIST gnome-desktop-40.0.tar.xz 721628 BLAKE2B ff89b8f4a284f63ee4c8b87f5b26542dabec13a4dcd75424f91acb21877699a5077d27bf4c618ea5e2c4cbd97570003c048296e24a8684021fb589238c09dfdf SHA512 faf6fd2a0c5db47a49319c03ca9a348d77092050cdd8d79a74979b2878d0e35ffa85bbe5e87449f9285ceb28a884439de6eb73d6b9fcaa02236eb48f4a7ac49c
diff --git a/gnome-base/gnome-desktop/gnome-desktop-40.0.ebuild b/gnome-base/gnome-desktop/gnome-desktop-40.0.ebuild
new file mode 100644
index 000000000000..b42b6b81c1b1
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-40.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? (
+		sys-apps/hwids
+		virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	x11-base/xorg-proto
+	virtual/pkgconfig
+"
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
+
+PATCHES=(
+	"${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
+)
+
+src_prepare() {
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}