gnome-extra/cinnamon-session: Remove old

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 94 deletions

diff --git a/gnome-extra/cinnamon-session/Manifest b/gnome-extra/cinnamon-session/Manifest
index 368861b9711f..50b61c3157ea 100644
--- a/gnome-extra/cinnamon-session/Manifest
+++ b/gnome-extra/cinnamon-session/Manifest
@@ -1,2 +1 @@
-DIST cinnamon-session-5.0.1.tar.gz 200036 BLAKE2B a7e254d54daa63f5dcf5592843b85e0c63a3fdd34ce5c3045ff5c7ce410f2ab340b5c778b1579e7586f7d9e0517fdf00703934395b9bbbbd234cb181a1096fcf SHA512 0c367764269ce1597035288508909aad2c031ab5b8c04bde3d81cc420f38abf6cca82f169db199cf01218e92014653f1749c0ed2096950f7bc9f3b56f1fcdebc
 DIST cinnamon-session-5.2.0.tar.gz 200208 BLAKE2B 2efe8ef0cb5dc4a828866c91bc020ffcc8b400423f92ac8be8ab47391202001123805c947af8e82eda530675b89cf4960f082b06acf24c296f083d6bcb941217 SHA512 3962529fed8d6c4c74e2f4b75014529d1a9b3307cf2d014c90088d0e2d3066ce375ccc3bbf5f07e9a181c08bba5360b07d5800cdb6386796255b4f1cb5c4d385
diff --git a/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild
deleted file mode 100644
index 119f516fc728..000000000000
--- a/gnome-extra/cinnamon-session/cinnamon-session-5.0.1.ebuild
+++ /dev/null
@@ -1,93 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9} )
-
-inherit meson gnome2-utils python-any-r1 xdg-utils
-
-DESCRIPTION="Cinnamon session manager"
-HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-session"
-SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 ~riscv x86"
-IUSE="doc ipv6 systemd"
-
-DEPEND="
-	>=dev-libs/glib-2.37.3:2
-	media-libs/libcanberra[pulseaudio]
-	virtual/opengl
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf:2
-	>=x11-libs/gtk+-3:3
-	x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXau
-	x11-libs/libXcomposite
-	x11-libs/libXext
-	x11-libs/libXrender
-	x11-libs/libXtst
-	x11-libs/pango[X]
-	>=x11-libs/xapp-2.2.0
-
-	systemd? ( >=sys-apps/systemd-183 )
-	!systemd? ( sys-auth/elogind[policykit] )
-"
-RDEPEND="
-	${DEPEND}
-	>=gnome-extra/cinnamon-desktop-5.0:0=
-"
-BDEPEND="
-	${PYTHON_DEPS}
-	dev-util/gdbus-codegen
-	>=dev-util/intltool-0.40.6
-	virtual/pkgconfig
-
-	doc? (
-		app-text/xmlto
-		dev-libs/libxslt )
-"
-
-src_prepare() {
-	default
-	python_fix_shebang data
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dgconf=false
-		$(meson_use doc docbook)
-		$(meson_use ipv6)
-	)
-	meson_src_configure
-}
-
-src_install() {
-	# A bit icky. Let the docs be installed in the wrong dir, then
-	# install them to the correct dir.
-	local dbus_doc_dir="${ED}/usr/share/doc/cinnamon-session/dbus"
-	use doc && local HTML_DOCS=( "$dbus_doc_dir" )
-
-	meson_src_install
-
-	# Clean-up the incorrectly installed docs.
-	# Fail if unhandled (new) files are encountered.
-	if use doc; then
-		rm -r "$dbus_doc_dir" || die
-		rm -d "${ED}/usr/share/doc/cinnamon-session" || die
-	fi
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	gnome2_schemas_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	gnome2_schemas_update
-}