gnome-extra/evolution-ews: Bump to 3.52.4

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index d240677ac889..3d15a4563b80 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -2,3 +2,4 @@ DIST evolution-ews-3.50.2.tar.xz 707800 BLAKE2B 18241eff067658af2f4620af87dea1c9
 DIST evolution-ews-3.50.3.tar.xz 708336 BLAKE2B e8fe4e2a6539142847d6610a61e2f57a83d604946270cd7b23d7e34fa89a38f644a05e452bbc03a6d96553936a38719afb7296eed03c7134735f937943d57114 SHA512 12c7fbe72f375837f185d4c8dbcb2167d327a0ad4b2ca822e4e5349d561e996e7a7405c6f8d36ceeddff0015286117db66a65d2756003aa8ca96948d7826e51f
 DIST evolution-ews-3.52.1.tar.xz 716152 BLAKE2B 91a4ff7ed1b9cb718a42a20bc08b4e12f10caf18534cd72e9f5cbe90161fbeb0af40bf52075a1a83e96f44ed6aac2cc4ad917e1ce49dcc0e26cd56f129b60951 SHA512 24f964019b08261e9b330a1b6663d835e07235e817aea4399c3dab1f35bf4bfb7543f82c91f23f6df6e56e0dff45d1f9ab23362d3603f9a64f6e1c63de75c450
 DIST evolution-ews-3.52.2.tar.xz 721964 BLAKE2B 53962e66f12e660f15c6fb300f30545d2380d5d12a1bce59ba64a44c7cefbdfaee2e1fa319e31e4c4c21cfd462e2c02aa96ee8efe78d4771bd8429aa18e89136 SHA512 b92db18b347c19fab15097aa7cedef876ca13364ece0ff2836cf6160bb2eb2ceb8d7eeaf9bada0369776ea32edca6938952a0dea04b229afd9690c744e16616c
+DIST evolution-ews-3.52.4.tar.xz 724244 BLAKE2B 35b78fa600e06c18cecee8c43941e77b3645a7d4487d72d989da62a0c7acab83f2adf4363c761d7e313f42175f341d63ec7709003599bf5b37e80424cc76d67c SHA512 017dbe28ba6524cdad1582cebd00fb675c75f52cac5875c756be0f402d4a0dd4a83e60b7ee0a2f71211eac49c04bba924e3d71775dce1e55fdcd372b1ac3747d
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.52.4.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.52.4.ebuild
new file mode 100644
index 000000000000..b8536add3667
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.52.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/evolution/-/wikis/home https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[glib]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" "gnome-extra/evolution-data-server[oauth-gtk3]"
+}