kde-apps/kate: drop 20.12.0*

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 107 deletions

diff --git a/kde-apps/kate/Manifest b/kde-apps/kate/Manifest
index f6c03689424c..dc24e999dac3 100644
--- a/kde-apps/kate/Manifest
+++ b/kde-apps/kate/Manifest
@@ -1,3 +1,2 @@
 DIST kate-20.08.3.tar.xz 5853216 BLAKE2B 8ad6f14e98e44355731497dd3363dab51e3f1658feadc398ba03629c13acb648f1a84e573bb200040008c0f3226f0ec1b6414a0975cf1ccc2cd1bfcebce1e125 SHA512 bb514f92a65ce7ff4e3552f16a400d10b30703340f779a1318403035900f32b2fd5c1da2ca0714632d49ad35da15e0f7e05a17bc008cd039388e89ab4fac3bd2
-DIST kate-20.12.0.tar.xz 5860660 BLAKE2B 459f15d0429fb72946aa060610d97c4450499ee904999623f0d0ace61195ab3166768bef5ca5b18d705f4c5f46655a3fa2a21ce36c98bdb5a0c6a63c260a02f2 SHA512 93ca4d40dff0c031d9d4899bd6cd29e9dd0efc64514cb5d75543d650afa99a469941a85f250008c86e96c1c92f4415121bfbaf0a2b12a788d0a36bdafb76cc6f
 DIST kate-20.12.1.tar.xz 5861052 BLAKE2B 204077aa95f5013acf477d5a6f3ac84d8349921a6d37970a5b2bcc5ff703d8cb66d4d27a0e61d82b76efcb741c249c07efc538ab833718ede253e91d7d70ed41 SHA512 23a3172c933a886186ac4a55d765cdbe26fe5871eddd645cd983584742e637b7e136d6ecb8e58e0a31e9e5956f92e23a56b839b9b74fb0635ea6a22ffc76c5f1
diff --git a/kde-apps/kate/kate-20.12.0.ebuild b/kde-apps/kate/kate-20.12.0.ebuild
deleted file mode 100644
index 0cabb56e29dd..000000000000
--- a/kde-apps/kate/kate-20.12.0.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=5.75.0
-QTMIN=5.15.1
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org optfeature
-
-DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
-HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/en/kate"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="activities +filebrowser lspclient +projects plasma +snippets sql telemetry"
-
-# only addons/externaltools depends on kiconthemes, too small for USE
-DEPEND="
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/kcodecs-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
-	filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:5 )
-	lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:5 )
-	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
-	projects? (
-		>=kde-frameworks/knewstuff-${KFMIN}:5
-		>=kde-frameworks/threadweaver-${KFMIN}:5
-	)
-	snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:5 )
-	sql? (
-		>=dev-qt/qtsql-${QTMIN}:5
-		>=kde-frameworks/kwallet-${KFMIN}:5
-	)
-	telemetry? ( dev-libs/kuserfeedback:5 )
-"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	ecm_src_prepare
-
-	# delete colliding kwrite translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "kwrite*" -delete || die
-		rm -rf po/*/docs/kwrite || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package activities KF5Activities)
-		-DBUILD_filebrowser=$(usex filebrowser)
-		-DBUILD_lspclient=$(usex lspclient)
-		-DBUILD_sessionapplet=$(usex plasma)
-		-DBUILD_project=$(usex projects)
-		-DBUILD_snippets=$(usex snippets)
-		-DBUILD_katesql=$(usex sql)
-		-DBUILD_kwrite=FALSE
-		$(cmake_use_find_package telemetry KUserFeedback)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# tests hang
-	local myctestargs=(
-		-E "(session_manager_test|sessions_action_test)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		elog "Optional dependencies:"
-		optfeature "Markdown text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
-		optfeature "DOT graph file previews" media-gfx/kgraphviewer
-	fi
-	ecm_pkg_postinst
-}