kde-plasma/plasma-firewall: 5.23.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 3f7c8fa145cf..375fe2063ba6 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.22.5.tar.xz 339372 BLAKE2B 332a7fd2be63429c452f43371b2875f8838e05b107a6c3472974c5db123eef9e415ec70601cb830a743d77422639225e01611e52c07a2b3fe079572278e2f638 SHA512 cc81884550b5c73061f5a1df24c0b32e5fff234a51e56153e95a9e4b0e23c305a555c2deff69633b9cd21dff7bfbcf5d9fcbd5ab3605d4ffa87be57514a91901
 DIST plasma-firewall-5.23.2.tar.xz 343908 BLAKE2B b88677569962203df015d20b56eccc47b14f08d7f58cecbbc4639287addb7a2c212ff6d887363cfb7f490db003ccd7254a9c095caa33be5a679c79d25015bd20 SHA512 6c6ab2d51d4a23290ce909a960451eb4cd45b2d5ef25f590e44182edf7b27c4c02961606a59cad65231a451507018b1740d671672ff1e54d53a859141ced158b
+DIST plasma-firewall-5.23.3.tar.xz 343956 BLAKE2B 1af8078508d778c2cf58f39578cc5ed68f2aaf5622e4a8c93f437f08c4161a9816495043dda6044b76cd3f7816f708b0327ab10f58f4f9daa412976208988cd2 SHA512 6f4341c8603df00df955a9ff6732f5874881a3c68b147211f7c420a0702bd5ea4a8126dbab3732d406b6e311fb500b099f2b56c034c280a93f8a4252d71330d7
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.23.3.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.23.3.ebuild
new file mode 100644
index 000000000000..dfd7cff04540
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.23.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.86.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}