media-libs/babl: fix missed dependencies

Fix missed lcms and gobject-introspection explicit dependencies

Closes: https://bugs.gentoo.org/723474

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 106 insertions, 1 deletions

diff --git a/media-libs/babl/babl-0.1.66-r1.ebuild b/media-libs/babl/babl-0.1.66-r1.ebuild
new file mode 100644
index 000000000000..5f6ba2b9f668
--- /dev/null
+++ b/media-libs/babl/babl-0.1.66-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999* ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
+	SRC_URI=""
+else
+	SRC_URI="http://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 -sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="http://www.gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="altivec lcms cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_mmx cpu_flags_x86_f16c"
+
+RDEPEND="lcms? ( >=media-libs/lcms-2.8:2 )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	econf \
+		--disable-docs \
+		--disable-static \
+		--disable-maintainer-mode \
+		$(use_enable altivec) \
+		$(use_enable cpu_flags_x86_f16c f16c) \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable cpu_flags_x86_sse3 sse3) \
+		$(use_enable cpu_flags_x86_sse4_1 sse4_1) \
+		$(use_with lcms)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
diff --git a/media-libs/babl/babl-0.1.74-r1.ebuild b/media-libs/babl/babl-0.1.74-r1.ebuild
new file mode 100644
index 000000000000..16fe9b5de136
--- /dev/null
+++ b/media-libs/babl/babl-0.1.74-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/babl.git"
+	SRC_URI=""
+else
+	SRC_URI="http://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 -sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="A dynamic, any to any, pixel format conversion library"
+HOMEPAGE="http://www.gegl.org/babl/"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="introspection lcms cpu_flags_x86_avx2 cpu_flags_x86_f16c cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	# Automagic rsvg support is just for website generation we do not call,
+	#     so we don't need to fix it
+	# w3m is used for dist target thus no issue for us that it is automagically
+	#     detected
+	local emesonargs=(
+		-Dwith-docs=false
+		$(meson_use introspection enable-gir)
+		$(meson_use lcms with-lcms)
+		$(meson_use cpu_flags_x86_avx2 enable-avx2)
+		$(meson_use cpu_flags_x86_f16c enable-f16c)
+		$(meson_use cpu_flags_x86_mmx enable-mmx)
+		$(meson_use cpu_flags_x86_sse enable-sse)
+		$(meson_use cpu_flags_x86_sse2 enable-sse2)
+		$(meson_use cpu_flags_x86_sse3 enable-sse3)
+		$(meson_use cpu_flags_x86_sse4_1 enable-sse4_1)
+	)
+	meson_src_configure
+}
diff --git a/media-libs/babl/babl-9999.ebuild b/media-libs/babl/babl-9999.ebuild
index e31e4dbc6a4d..16fe9b5de136 100644
--- a/media-libs/babl/babl-9999.ebuild
+++ b/media-libs/babl/babl-9999.ebuild
@@ -22,7 +22,10 @@ SLOT="0"
 IUSE="introspection lcms cpu_flags_x86_avx2 cpu_flags_x86_f16c cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_sse4_1"
 
 BDEPEND="virtual/pkgconfig"
-RDEPEND="lcms? ( media-libs/lcms:2 )"
+RDEPEND="
+	introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+	lcms? ( >=media-libs/lcms-2.8:2 )
+"
 DEPEND="${RDEPEND}"
 
 src_configure() {