media-libs/libbluray: add 1.3.0

* Bump to 1.3.0
* Use system copy of libudfread
* Update Java dependency as per fordfrog@'s email to gentoo-dev

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 95 insertions, 16 deletions

diff --git a/media-libs/libbluray/Manifest b/media-libs/libbluray/Manifest
index 97df0a151ad3..1894f9864c1a 100644
--- a/media-libs/libbluray/Manifest
+++ b/media-libs/libbluray/Manifest
@@ -1,2 +1,3 @@
 DIST libbluray-1.2.0.tar.bz2 747265 BLAKE2B d9f0d1c321faa9008431b17aecba495e44d2795cea2973f9772b5be2c0193af53e3c947b9dd0b2d4d22c4085e163461252f895618e98491184d85eb7fbf5bd54 SHA512 d10413b6b86ff2d2e7c4b0103546f2142727cc5209ddb7b227aa74e27384f2e0b9abee37bf8ccc5b0cdfcaeebfb0669cf20903a247df278a8ad6dbd27469d324
 DIST libbluray-1.2.1.tar.bz2 751063 BLAKE2B af353e03a70b0202776c2190d927506225bbe1147fe5bfb19039839f5d82d0beb4fd7c2813a9ce10a2bc6f9d07e2a2080b54f1442e02e5f8e72564a5bcaf0a2a SHA512 e9eeee433034266e88c05ae3469c0bd2bf700d7f16e17ad706f48426c143c823e83c16ab79a637f1e85e4eb858aa0577630671f87ba35d179db2a1d8bc8545c4
+DIST libbluray-1.3.0.tar.bz2 754069 BLAKE2B d4c699ce28d2e5b1d4dda461a1359d3a446afe72368e9d76066ca4d5c49d1f24b4bcec307608d96913d0c668168a86267416b9db37ad942628c2926b79ec47d9 SHA512 3d5145e6fd7de099c07f937282112c7abb12a5590b7c0b965b00bddee3837ddfd1a30076aaa6d6278d07a5beee3856f602125983ae075ab30eceb6ac1bd9bcdc
diff --git a/media-libs/libbluray/libbluray-1.3.0.ebuild b/media-libs/libbluray/libbluray-1.3.0.ebuild
new file mode 100644
index 000000000000..5300670e9218
--- /dev/null
+++ b/media-libs/libbluray/libbluray-1.3.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ "${PV#9999}" != "${PV}" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://code.videolan.org/videolan/libbluray.git"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	SRC_URI="https://downloads.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"
+fi
+
+inherit autotools java-pkg-opt-2 flag-o-matic multilib-minimal
+
+DESCRIPTION="Blu-ray playback libraries"
+HOMEPAGE="https://www.videolan.org/developers/libbluray.html"
+
+LICENSE="LGPL-2.1"
+SLOT="0/2"
+IUSE="aacs bdplus +fontconfig java static-libs +truetype utils +xml"
+
+RDEPEND="
+	dev-libs/libudfread[${MULTILIB_USEDEP}]
+	aacs? ( >=media-libs/libaacs-0.6.0[${MULTILIB_USEDEP}] )
+	bdplus? ( media-libs/libbdplus[${MULTILIB_USEDEP}] )
+	fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
+	java? ( >=virtual/jre-1.8:* )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}] )
+	xml? ( >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	java? ( >=virtual/jdk-1.8:* )
+"
+BDEPEND="
+	virtual/pkgconfig
+	java? (
+		dev-java/ant-core
+		>=virtual/jdk-1.6
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-jars.patch
+)
+
+DOCS=( ChangeLog README.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	use java || unset JDK_HOME # Bug #621992.
+
+	ECONF_SOURCE="${S}" econf \
+		--disable-optimizations \
+		$(multilib_native_use_enable utils examples) \
+		$(multilib_native_use_enable java bdjava-jar) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_enable static-libs static) \
+		$(use_with xml libxml2)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	multilib_is_native_abi || return
+
+	use utils &&
+		find .libs/ -type f -executable ! -name "${PN}.*" \
+			 $(use java || echo '! -name bdj_test') -exec dobin {} +
+
+	use java &&
+		java-pkg_regjar "${ED}"/usr/share/${PN}/lib/*.jar
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-libs/libbluray/libbluray-9999.ebuild b/media-libs/libbluray/libbluray-9999.ebuild
index e0edf9695213..64c86568e0f7 100644
--- a/media-libs/libbluray/libbluray-9999.ebuild
+++ b/media-libs/libbluray/libbluray-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -7,7 +7,7 @@ if [[ "${PV#9999}" != "${PV}" ]] ; then
 	inherit git-r3
 	EGIT_REPO_URI="https://code.videolan.org/videolan/libbluray.git"
 else
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 	SRC_URI="https://downloads.videolan.org/pub/videolan/libbluray/${PV}/${P}.tar.bz2"
 fi
 
@@ -20,37 +20,32 @@ LICENSE="LGPL-2.1"
 SLOT="0/2"
 IUSE="aacs bdplus +fontconfig java static-libs +truetype utils +xml"
 
-COMMON_DEPEND="
-	xml? ( >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}] )
-	fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
-	truetype? ( >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}] )
-"
 RDEPEND="
-	${COMMON_DEPEND}
+	dev-libs/libudfread[${MULTILIB_USEDEP}]
 	aacs? ( >=media-libs/libaacs-0.6.0[${MULTILIB_USEDEP}] )
 	bdplus? ( media-libs/libbdplus[${MULTILIB_USEDEP}] )
+	fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
 	java? ( >=virtual/jre-1.6 )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}] )
+	xml? ( >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}] )
 "
 DEPEND="
-	${COMMON_DEPEND}
+	${RDEPEND}
 	java? ( >=virtual/jdk-1.6 )
 "
 BDEPEND="
+	virtual/pkgconfig
 	java? (
-		>=virtual/jdk-1.6
 		dev-java/ant-core
+		>=virtual/jdk-1.6
 	)
-	virtual/pkgconfig
 "
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-jars.patch
 )
 
-DOCS=(
-	ChangeLog
-	README.txt
-)
+DOCS=( ChangeLog README.txt )
 
 src_prepare() {
 	default
@@ -84,5 +79,5 @@ multilib_src_install() {
 
 multilib_src_install_all() {
 	einstalldocs
-	find "${D}" -name '*.la' -delete || die
+	find "${ED}" -name '*.la' -delete || die
 }