media-libs/libcdr: Version bump

Package-Manager: portage-2.2.27

1 files changed, 51 insertions, 0 deletions

diff --git a/media-libs/libcdr/libcdr-0.1.2.ebuild b/media-libs/libcdr/libcdr-0.1.2.ebuild
new file mode 100644
index 000000000000..dd033dac8721
--- /dev/null
+++ b/media-libs/libcdr/libcdr-0.1.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/libreoffice/libcdr/"
+inherit base eutils
+[[ ${PV} == 9999 ]] && inherit autotools git-2
+
+DESCRIPTION="Library parsing the Corel cdr documents"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libcdr"
+[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86"
+IUSE="doc static-libs"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	media-libs/lcms:2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	base_src_prepare
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable static-libs static) \
+		--disable-werror \
+		$(use_with doc docs)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}