media-libs/libmediainfo: version bump to 0.7.91

2 files changed, 85 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index d897611d4186..6138c9128f16 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1,2 +1,3 @@
 DIST libmediainfo_0.7.89.tar.xz 1566172 SHA256 2cd3da0cc3e23bbfddea545898df6ebc1c81e086a1d707ac6d2068fe659ea74a SHA512 0289a4d9a6b27bc6fce1b1aebbc64495ef220bdbdb36c851b4ca345ac7b5dfc8d06b03c1cfb36ee7a736ff4a1d9e2da53d5f2d3559c5297e1c41f8a98f04737a WHIRLPOOL cc986916e6a877c512320bf59bdfb0073f2dae8bc8d6ccffc2080305530e233bff60cbbade8333bc62827c636185e0b3433746639e22887cd8b0b52a5976b8bb
 DIST libmediainfo_0.7.90.tar.xz 1578580 SHA256 85551ba92802df3f5e1026b3752c6d4b7cae1304b783de7b893a27cdefa9a795 SHA512 49a5dc9532bb1fb3aebef4476346089f685b6782b9b380fde5822ae97680bbc0db22f45a5a2e9b17a7cf2947696e10eda233771b50f8ab7bfb54b250620c3fcb WHIRLPOOL 2256bc5b4b20a9a0cccc2ffa79c180aa5bb22a49d339d3b13e3369a45f4323f41a36a43c953bfdf0baf6fa461f2affa6d3622be2be8b6b493425759bdf202a57
+DIST libmediainfo_0.7.91.tar.xz 1575876 SHA256 28818b88cedc8d5bc6b6c2a32d37ec456cb9784b4bf105416ef1e5821a6769c0 SHA512 7b05ae099cd8fd1f1f4134a16cff407bd6016095bad8769444f14eecd34b3771634c9a59f4fb41b04f5fc0381cf755ef1d5cbd05fd0bee57fcafacbb52293f5c WHIRLPOOL f86664ce7931f08f17370ece5e20669a3762ab9cc51532dfd00ce05b0081335863795bb9de966566bf006076a579b3f23023ab40804f07355e57c4b6ece66c51
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.91.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.91.ebuild
new file mode 100644
index 000000000000..2b934ef8d103
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.91.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediaarea.net/mediainfo/"
+SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.34[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	prune_libtool_files
+}