media-sound/gmusicbrowser: drop gstreamer-0 support

close bug #604684
Closes: https://github.com/gentoo/gentoo/pull/3955

2 files changed, 71 insertions, 9 deletions

diff --git a/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r3.ebuild b/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r3.ebuild
new file mode 100644
index 000000000000..6a5db3941185
--- /dev/null
+++ b/media-sound/gmusicbrowser/gmusicbrowser-1.1.15-r3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="An open-source jukebox for large collections of mp3/ogg/flac files"
+HOMEPAGE="http://gmusicbrowser.org/"
+SRC_URI="http://${PN}.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus doc extras gstreamer libnotify mplayer"
+
+GSTREAMER_DEPEND="dev-perl/Glib-Object-Introspection"
+MPLAYER_DEPEND="media-video/mplayer"
+MPV_DEPEND="media-video/mpv"
+OTHER_DEPEND="
+	media-sound/alsa-utils
+	media-sound/flac123
+	|| ( media-sound/mpg123 media-sound/mpg321 )
+	media-sound/vorbis-tools"
+
+RDEPEND="dev-lang/perl
+	dev-perl/gtk2-perl
+	virtual/perl-MIME-Base64
+	|| ( net-misc/wget dev-perl/AnyEvent-HTTP )
+	dbus? ( dev-perl/Net-DBus )
+	gstreamer? ( ${GSTREAMER_DEPEND} )
+	mplayer? ( || ( ${MPLAYER_DEPEND} ${MPV_DEPEND} ) )
+	!gstreamer? ( !mplayer? ( ${OTHER_DEPEND} ) )
+	extras? ( dev-perl/gnome2-wnck )
+	libnotify? ( dev-perl/Gtk2-Notify )"
+DEPEND="sys-devel/gettext"
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		iconsdir="${D%/}/usr/share/icons/hicolor" \
+		install
+
+	use doc && local HTML_DOCS=( layout_doc.html )
+	einstalldocs
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+
+	elog "Gmusicbrowser supports gstreamer, mplayer, mpv and mpg123/ogg123..."
+	elog "for audio playback. Needed dependencies:"
+	elog "  Gstreamer: ${GSTREAMER_DEPEND}"
+	elog "  mplayer: ${MPLAYER_DEPEND}"
+	elog "  mpv: ${MPV_DEPEND}"
+	elog "  mpg123/ogg123...: ${OTHER_DEPEND}"
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild b/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
index c2c17f37fffc..ad13158cc9a4 100644
--- a/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
+++ b/media-sound/gmusicbrowser/gmusicbrowser-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
@@ -13,13 +13,9 @@ EGIT_REPO_URI="git://github.com/squentin/${PN}.git"
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS=""
-IUSE="dbus doc extras gstreamer gstreamer-0 libnotify mplayer"
+IUSE="dbus doc extras gstreamer libnotify mplayer"
 
 GSTREAMER_DEPEND="dev-perl/Glib-Object-Introspection"
-GSTREAMER0_DEPEND="
-	dev-perl/GStreamer
-	dev-perl/GStreamer-Interfaces
-	media-plugins/gst-plugins-meta:0.10"
 MPLAYER_DEPEND="media-video/mplayer"
 MPV_DEPEND="media-video/mpv"
 OTHER_DEPEND="
@@ -34,9 +30,8 @@ RDEPEND="dev-lang/perl
 	|| ( net-misc/wget dev-perl/AnyEvent-HTTP )
 	dbus? ( dev-perl/Net-DBus )
 	gstreamer? ( ${GSTREAMER_DEPEND} )
-	gstreamer-0? ( ${GSTREAMER0_DEPEND} )
 	mplayer? ( || ( ${MPLAYER_DEPEND} ${MPV_DEPEND} ) )
-	!gstreamer? ( !gstreamer-0? ( !mplayer? ( ${OTHER_DEPEND} ) ) )
+	!gstreamer? ( !mplayer? ( ${OTHER_DEPEND} ) )
 	extras? ( dev-perl/gnome2-wnck )
 	libnotify? ( dev-perl/Gtk2-Notify )"
 DEPEND="sys-devel/gettext
@@ -67,7 +62,6 @@ pkg_postinst() {
 	elog "Gmusicbrowser supports gstreamer, mplayer, mpv and mpg123/ogg123..."
 	elog "for audio playback. Needed dependencies:"
 	elog "  Gstreamer: ${GSTREAMER_DEPEND}"
-	elog "  Gstreamer-0.10: ${GSTREAMER0_DEPEND}"
 	elog "  mplayer: ${MPLAYER_DEPEND}"
 	elog "  mpv: ${MPV_DEPEND}"
 	elog "  mpg123/ogg123...: ${OTHER_DEPEND}"