media-sound/sox: security bump to 20200803 snapshot

Bug: https://bugs.gentoo.org/711320
Closes: https://bugs.gentoo.org/712630
Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 107 insertions, 0 deletions

diff --git a/media-sound/sox/Manifest b/media-sound/sox/Manifest
index c56a4c58f4c7..c561e3e27dc8 100644
--- a/media-sound/sox/Manifest
+++ b/media-sound/sox/Manifest
@@ -1 +1,2 @@
 DIST sox-14.4.2.tar.gz 1134299 BLAKE2B 9fae987d421fc733b84746f8dc8f09ced1c3ce066643a426d7c64c4ed4ceeb18e5d00165108b39065a4ce40ff39e9d020fc6e734ff1121ee39bfeed4ad822bc5 SHA512 b5c6203f4f5577503a034fe5b3d6a033ee97fe4d171c533933e2b036118a43a14f97c9668433229708609ccf9ee16abdeca3fc7501aa0aafe06baacbba537eca
+DIST sox-14.4.2_p20200803.zip 1089835 BLAKE2B fa53d8c9f14620675bf534090bf6c69ec256bb977aa1b3c01b2d95ba8e685eb4f9d479872f303b2954aa1b063c095bf3b90e5b746fd8d7d66e35476e5218fa6b SHA512 8c485a53b9ecce9ecf759d7bbf8d95e568a89505bec7d1258afded4c7ad0f28c624b637a188ab87b64dee720db59b8de20c347805910f0401f00550832e16392
diff --git a/media-sound/sox/sox-14.4.2_p20200803.ebuild b/media-sound/sox/sox-14.4.2_p20200803.ebuild
new file mode 100644
index 000000000000..180bf99760e3
--- /dev/null
+++ b/media-sound/sox/sox-14.4.2_p20200803.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+# We take a snapshot because of the huge number of security
+# and other fixes since the release of 14.4.2.
+# Recommend mirroring the snapshot; unclear if they are stable URIs.
+COMMIT="50857c46c03a85c72826e819f5e815aad4a4633d"
+MY_P="sox-code-${COMMIT}"
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="http://sox.sourceforge.net"
+# Source: https://sourceforge.net/code-snapshots/git/s/so/sox/code.git/${MY_P}.zip
+SRC_URI="https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${MY_P}.zip -> ${P}.zip"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="alsa amr ao debug encode flac id3tag ladspa mad ogg openmp oss opus png pulseaudio sndfile static-libs twolame wavpack"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-libs/libltdl:0=
+	>=media-sound/gsm-1.0.12-r1
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ao? ( media-libs/libao )
+	encode? ( >=media-sound/lame-3.98.4 )
+	flac? ( >=media-libs/flac-1.1.3 )
+	id3tag? ( media-libs/libid3tag )
+	ladspa? ( media-libs/ladspa-sdk )
+	mad? ( media-libs/libmad )
+	ogg? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	opus? (
+		media-libs/opus
+		media-libs/opusfile
+	)
+	png? (
+		media-libs/libpng:0=
+		sys-libs/zlib
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( >=media-libs/libsndfile-1.0.11 )
+	twolame? ( media-sound/twolame )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS )
+
+src_prepare() {
+	default
+
+	# bug #386027
+	sed -i -e 's:CFLAGS="-g":CFLAGS="$CFLAGS -g":' configure.ac || die
+
+	# bug #712630
+	if use elibc_musl ; then
+		ewarn "Applying musl workaround for bug #712630."
+		ewarn "File-type detection with pipes may be missing."
+		sed -i '/error FIX NEEDED HERE/d' src/formats.c || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with alsa) \
+		$(use_with amr amrnb) \
+		$(use_with amr amrwb) \
+		$(use_with ao) \
+		$(use_enable debug) \
+		$(use_with encode lame) \
+		$(use_with flac) \
+		$(use_with id3tag) \
+		$(use_with ladspa) \
+		$(use_with mad) \
+		$(use_enable openmp) \
+		$(use_with ogg oggvorbis) \
+		$(use_with oss) \
+		$(use_with opus) \
+		$(use_with png) \
+		$(use_with pulseaudio) \
+		$(use_with sndfile) \
+		$(use_enable static-libs static) \
+		$(use_with twolame) \
+		$(use_with wavpack) \
+		--with-distro="Gentoo"
+}
+
+src_install() {
+	default
+	# libltdl is used for loading plugins, keeping libtool files with empty
+	# dependency_libs what otherwise would be -exec rm -f {} +
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}